PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# $Id: PKGBUILD 264438 2016-04-09 13:49:25Z foutrelis $
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: Daniel Balieiro <daniel@balieiro.com>
# Contributor: Rodrigo L. M. Flores <mail@rodrigoflores.org>
_pkgname=telepathy-gabble
pkgname=${_pkgname}-xep0198-git
pkgver=0.18.1.r185.gfc4a8c7
pkgrel=1
pkgdesc="A Jabber/XMPP connection manager for Telepathy with XEP-0198_Stream_Management"
arch=('i686' 'x86_64')
url="http://telepathy.freedesktop.org"
groups=('telepathy')
license=('LGPL2.1')
depends=('telepathy-glib' 'libsoup' 'libnice' 'sqlite')
makedepends=('libxslt' 'python' 'gnome-common')
conflicts=($_pkgname)
provides=($_pkgname)
options=('!emptydirs')
source=(git+https://github.com/Thaodan/telepathy-gabble.git#branch=wocky_update)
md5sums=('SKIP')
install=telepathy-gabble.install

pkgver()
{
  cd $_pkgname
  git describe --always --long | sed -E 's/telepathy-gabble.//;s/([^-]*-g)/r\1/;s/-/./g;'

}

prepare()
{
  cd $_pkgname
  ./autogen.sh  --no-configure
}
build() {
  cd $_pkgname
  PYTHON=/usr/bin/python ./configure --prefix=/usr \
  	--libexecdir=/usr/lib/telepathy \
    --disable-Werror  --enable-gtk-doc
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $_pkgname
  make DESTDIR="$pkgdir" install
}