PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: HurricanePootis <hurricanepootis@protonmail.com>
pkgname=the-honkers-railway-launcher
pkgver=1.15.2
pkgrel=1
pkgdesc="The Honkers Railway launcher for Linux with automatic patching and telemetry disabling"
arch=('x86_64')
url="https://github.com/an-anime-team/the-honkers-railway-launcher"
license=('GPL-3.0-only')
depends=('gtk4' 'libadwaita' 'glibc' 'hicolor-icon-theme' 'libgcc' 'glib2' 'gdk-pixbuf2'
	 'pango' 'xz' 'bzip2' 'cairo' 'p7zip' 'wayland' 'git' 'libwebp-utils'
	 'winetricks')
makedepends=('cargo')
optdepends=(
	 'mangohud: FPS Overlay'
	 'gamescope: Micro-Compositor'
	 'gamemode: CPU Scaling Control')
source=("$url/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('8bca00ada1224a3e00787c6b88d9cc4b7cce52a51e2a3c9c0bd5eae6101ba86b')

prepare() {
	cd "$srcdir/$pkgname-$pkgver"
	export RUSTUP_TOOLCHAIN=stable
	cargo fetch --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
	cd "$srcdir/$pkgname-$pkgver"
    	export RUSTUP_TOOLCHAIN=stable
    	export CARGO_TARGET_DIR=target
	export CFLAGS+=" -ffat-lto-objects"
	cargo build --frozen --release --all-features
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	install -Dm755 "target/release/${pkgname:4}" "$pkgdir/usr/bin/${pkgname:4}"
	install -Dm644 "assets/${pkgname:4}.desktop" "$pkgdir/usr/share/applications/${pkgname:4}.desktop"
	install -Dm644 "assets/images/icon.png" "$pkgdir/usr/share/icons/hicolor/512x512/apps/moe.launcher.${pkgname}.png"
	install -dm755 "$pkgdir/usr/share/pixmaps"
	ln -s "/usr/share/icons/hicolor/512x512/apps/moe.launcher.${pkgname}.png" "$pkgdir/usr/share/pixmaps/${pkgname:4}.png"
	sed -i "s/Exec=AppRun/Exec=${pkgname:4}/g" "$pkgdir/usr/share/applications/${pkgname:4}.desktop"
	sed -i "s/Icon=icon/Icon=${pkgname:4}/g" "$pkgdir/usr/share/applications/${pkgname:4}.desktop"
	echo "StartupWMClass=moe.launcher.${pkgname}" >> "$pkgdir/usr/share/applications/${pkgname:4}.desktop"
}