summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: d49a22788780f9b5c6c550ff9f4b897041100beb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Maintainer: Cody Schafer <aur at codyps.com>

_pkgbase=theft
pkgname=theft-git
pkgver=0.4.4.r0.ge2e46b4
pkgrel=2
pkgdesc="property-based testing for C"
arch=('i686' 'x86_64')
url="https://github.com/silentbicycle/theft"
license=('ISC')
depends=()
makedepends=('git')
provides=(theft)
conflicts=(theft)

source=(
  "$pkgname::git+https://github.com/silentbicycle/theft.git"
  "file://0001-make-set-permisions.patch"
  "file://0001-rework-Makefile-to-allow-overriding-CFLAGS-when-pack.patch"
)
sha256sums=('SKIP'
            'f9396d19b0b07a8becd9c8bcfdd0765d5da893e65e945f51e5d7a5c9d96fa831'
            '2896151725ccd5d66397d4d91398a9b1f2144861ce0a97409b16363f90ee24cc')

pkgver() {
  cd "${srcdir}/${pkgname}"
  git describe --tags --long | sed -E 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/${pkgname}"
  patch -Np1 <"$srcdir/0001-make-set-permisions.patch"
  patch -Np1 <"$srcdir/0001-rework-Makefile-to-allow-overriding-CFLAGS-when-pack.patch"
}

build() {
  cd "$srcdir/${pkgname}"
  make PREFIX=/usr
}

package() {
  cd "$srcdir/${pkgname}"
  make PREFIX=/usr PKGCONFIG_DST=/usr/lib/pkgconfig DESTDIR="${pkgdir}" install
  mkdir -p "$pkgdir/usr/share/licenses/$pkgname"
  install -D -m644 ./LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  mkdir -p "$pkgdir/usr/share/doc/$_pkgbase"
  for i in doc/*.md; do
    install -m644 "$i" "$pkgdir/usr/share/doc/$_pkgbase"
  done
}

# ex: sts=2:ts=2:sw=2:et