blob: be5184e3ad9d32ee4cfa93ebabc88b79896b3317 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=thiefmd
pkgver=0.2.7
pkgrel=2
pkgdesc="The markdown editor worth stealing. Inspired by Ulysses, based on code from Quilter"
arch=('x86_64' 'aarch64')
url="https://thiefmd.com"
license=('GPL-3.0-or-later')
depends=(
'clutter'
'discount'
'gtksourceview4'
'gtkspell3'
'libarchive'
'libgee'
'link-grammar'
'libhandy'
'webkit2gtk-4.1'
)
makedepends=(
'git'
'meson'
'vala'
)
source=("git+https://github.com/kmwallio/ThiefMD.git#tag=v$pkgver"
'git+https://github.com/flathub/shared-modules.git'
'git+https://github.com/ThiefMD/libwritegood-vala.git'
'git+https://github.com/TwiRp/ultheme-vala.git'
'git+https://github.com/ThiefMD/writeas-vala.git'
'git+https://github.com/ThiefMD/ghost-vala.git'
'git+https://github.com/ThiefMD/custom-gtksourceview-languages.git'
'git+https://github.com/ThiefMD/wordpress-vala.git'
'git+https://github.com/ThiefMD/BiBtex-vala.git'
'git+https://github.com/ThiefMD/medium-vala.git'
'git+https://github.com/ThiefMD/forem-vala.git'
'git+https://github.com/TwiRp/hashnode-vala.git')
sha256sums=('59e0c234788e9001b372049e143f9a75a39a95a906fe241d014af9428b48c3c4'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP')
prepare() {
cd ThiefMD
git submodule init
git config submodule.flatpak/shared-modules.url "$srcdir/shared-modules"
git config submodule.src/writegood.url "$srcdir/libwritegood-vala"
git config submodule.src/ultheme.url "$srcdir/ultheme-vala"
git config submodule.src/writeas.url "$srcdir/writeas-vala"
git config submodule.src/ghost.url "$srcdir/ghost-vala"
git config submodule.data/language-specs.url "$srcdir/custom-gtksourceview-languages"
git config submodule.src/wordpress.url "$srcdir/wordpress-vala"
git config submodule.src/bibtex.url "$srcdir/BiBtex-vala"
git config submodule.src/medium.url "$srcdir/medium-vala"
git config submodule.src/forem.url "$srcdir/forem-vala"
git config submodule.src/hashnode.url "$srcdir/hashnode-vala"
git -c protocol.file.allow=always submodule update
}
build() {
arch-meson ThiefMD build
meson compile -C build
}
# Requires build_tests=true
#check() {
# meson test -C build --print-errorlogs
#}
package() {
meson install -C build --destdir "$pkgdir"
ln -s "/usr/bin/com.github.kmwallio.$pkgname" "$pkgdir/usr/bin/$pkgname"
}
|