blob: 90feb37f2c7811beb60681fc3a1b44e644c6579a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Victor <v1c70rp at gmail dot com>
_pkgname=thrust
pkgname=thrust-git
pkgver=1.9.10.r60.g52a8bda4
pkgrel=1
pkgdesc='A C++ parallel programming library which resembles the C++ Standard Library'
arch=('any')
url="https://github.com/thrust/${_pkgname}"
license=('Apache')
provides=('thrust')
conflicts=('thrust')
makedepends=('git')
depends=()
optdepends=(
'cuda: for CUDA backend'
'openmp: for OMP backend'
'intel-tbb: for TBB backend'
)
source=("git+https://github.com/thrust/${_pkgname}.git"
"git+https://github.com/thrust/cub.git")
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd "${_pkgname}"
git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${_pkgname}"
git submodule init
git config submodule.cub.url "${srcdir}/cub"
git submodule update
}
package() {
install -dm 755 "${pkgdir}/opt/${_pkgname}"
cd "${srcdir}/${_pkgname}"
cp -r ${_pkgname} "${pkgdir}/opt/${_pkgname}/"
cp -r examples "${pkgdir}/opt/${_pkgname}/"
cp -rL cub "${pkgdir}/opt/${_pkgname}/"
}
# vim: ft=sh ts=2 sw=2 et
|