blob: a18e119de3084e714f6c741785ed4d6b667dabce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Igor <f2404@yandex.ru>
# Contributor: Davi da Silva Böger <dsboger at gmail dot com>
pkgname=tilix-git
pkgver=1.9.6.r20.g1405af0b
pkgrel=2
pkgdesc="A tiling terminal emulator for Linux using GTK+ 3"
arch=('x86_64')
url="https://gnunn1.github.io/tilix-web"
license=('MPL-2.0')
depends=(
'dconf'
'gsettings-desktop-schemas'
'gtkd'
'liblphobos'
'libx11'
'vte3'
)
makedepends=(
'git'
'ldc'
'meson'
'po4a'
)
checkdepends=(
'appstream'
)
optdepends=(
'python-nautilus: for "Open Tilix Here" support in nautilus'
'libsecret: for the password manager'
'vte3-notification: for desktop notifications support'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/gnunn1/tilix.git')
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${pkgname%-git}"
}
build() {
# Build with LDC
export DC=ldc
export LDFLAGS="$(echo -ne $LDFLAGS | sed -e 's/-flto=auto//')"
export DFLAGS="--flto=full"
arch-meson "${pkgname%-git}" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs || :
appstreamcli validate --no-net build/data/com.gexperts.Tilix.appdata.xml || :
}
package() {
meson install -C build --destdir "$pkgdir"
}
|