blob: 64df0c11b639eee0ae75b47ce29f3269f101c702 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Florian Loitsch <florian@toit.io>
pkgname=toit
_tag="v2.0.0-alpha.149"
_repo="https://github.com/toitlang/toit.git"
_commit=14251f1ee8675ddd6b372b11ca1e26f3359d3b24
_tag_no_dash="${_tag//-/}"
pkgver="${_tag_no_dash#v}"
pkgrel=1
pkgdesc="Toit programming language SDK"
arch=('x86_64')
url="https://toitlang.org"
license=('LGPL')
depends=('gcc-libs' 'esptool')
optdepends=("toit-vessels-bin=$pkgver: Vessels for cross-compilation")
makedepends=(
'git'
'cmake'
'ninja'
'go'
# For xxd.
'vim'
)
source=("git+$_repo#commit=$_commit")
noextract=()
md5sums=('SKIP')
prepare() {
cd "$srcdir/${pkgname%-git}"
# Initialize the top-level modules but not nested ones.
git submodule update --depth=1 --init .
cd third_party/esp-idf
# We only need mbedtls of the esp-idf submodule to build the host tools.
# Don't bother initializing all the other components.
git submodule update --depth=1 --init components/mbedtls
}
build() {
cd "$srcdir/${pkgname%-git}"
TOIT_GIT_VERSION=$_tag make -j1 sdk
}
package() {
cd "$srcdir/${pkgname%-git}"
make DESTDIR="$pkgdir/" install
mkdir -p "$pkgdir/usr/bin"
ln -s "/opt/toit-sdk/bin/toit" "$pkgdir/usr/bin"
ln -s "/opt/toit-sdk/bin/toit.run" "$pkgdir/usr/bin"
ln -s "/opt/toit-sdk/bin/toit.compile" "$pkgdir/usr/bin"
ln -s "/opt/toit-sdk/bin/toit.pkg" "$pkgdir/usr/bin"
ln -s "/opt/toit-sdk/bin/toit.lsp" "$pkgdir/usr/bin"
}
|