PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Julian Brost <julian@0x4a42.net>

pkgname=trac-svn
pkgver=1.6.r17714
pkgrel=1
pkgdesc='Enhanced wiki and issue tracking system for software development projects, SVN version'
arch=('any')
url="https://trac.edgewall.org/"
license=('BSD')
depends=(python python-jinja python-setuptools)
makedepends=(subversion python-babel)
optdepends=('python-psycopg2: PostgreSQL database support'
            'python-pygments: Syntax highlighting'
            'python-docutils: reStructuredText support'
            'python-babel: localization support'
            'python-pytz: complete list of time zones')
provides=(trac)
conflicts=(trac)
source=('trac::svn+https://svn.edgewall.org/repos/trac/trunk/')
sha256sums=(SKIP)

pkgver() {
	cd "$srcdir/trac"
	local ver=$(sed -n '/^version\s*=\s*/s/^version\s*=\s*//p' < setup.cfg)
	local rev=$(svnversion)
	printf "%s.r%s" "$ver" "${rev//[[:alpha:]]}"
}

package() {
	cd "$srcdir/trac"
	python setup.py egg_info --tag-build="dev$(svnversion)" install --prefix=/usr --root="$pkgdir" --optimize=1
	install -D -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}