PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: mia <mia@mia.jetzt>

pkgname=tree-sitter-toml
pkgver=0.5.1
pkgrel=1
pkgdesc='Toml grammar for tree-sitter with queries'
arch=('x86_64')
_reponame=tree-sitter-toml
url=https://github.com/ikatyang/$_reponame
license=('MIT')
makedepends=('git' 'tree-sitter-cli' 'npm')
source=("source.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
conflicts=('tree-sitter-toml')
sha256sums=('23be3c5d7e65b60460f2a31994c808cfc154aab2ac93c4f51041525986bee337')

prepare() {
  cd $_reponame-$pkgver
  tree-sitter generate --no-bindings src/grammar.json
}

build() {
  cd $_reponame-$pkgver/src
  cc $CFLAGS -I. -std=c99 -c parser.c scanner.c
  cc $LDFLAGS -shared parser.o scanner.o -o "$srcdir/parser.so"
}

package() {
	install -Dvm 644 parser.so "$pkgdir/usr/lib/lib$_reponame.so.0.0"
  install -d "$pkgdir"/usr/lib/tree_sitter
  ln -s /usr/lib/lib$_reponame.so.0.0 "$pkgdir"/usr/lib/tree_sitter/${_reponame#tree-sitter-}.so
  ln -s lib$_reponame.so.0.0 "$pkgdir/usr/lib/lib$_reponame.so.0"
  ln -s lib$_reponame.so.0.0 "$pkgdir/usr/lib/lib$_reponame.so"

  cd $_reponame-$pkgver
  install -Dm644 -t "$pkgdir"/usr/share/doc/$_reponame README.md
  install -Dm644 -t "$pkgdir"/usr/share/licenses/$_reponame LICENSE
  install -Dm644 -t "$pkgdir"/usr/share/tree-sitter/queries/toml queries/*
}