blob: f8791704dd48f7912c29ec82336f9809ffa33f17 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: Sylvester Keil <sylvester@keil.or.at>
pkgname='tropy'
pkgver='1.16.2'
pkgrel=1
pkgdesc='Explore your research photos'
arch=('x86_64')
url='https://tropy.org'
license=('AGPL-3.0-or-later')
depends=(
'electron28'
'gcc-libs'
'glib2'
'glibc'
'hicolor-icon-theme'
'libvips'
'sh'
'xdg-utils')
optdepends=(
'libheif: for heif support'
'imagemagick: for loading loading images via imagemagick'
'poppler-glib: for pdf support')
makedepends=(
'nodejs'
'python3')
provides=('tropy')
conflicts=('tropy-bin' 'tropy-appimage')
source=(
'tropy.sh'
"https://github.com/tropy/tropy/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('33a0ee41a99156cf8986b3771ba8fea38b0d23d75fc09bef0f1254fe4fb47952'
'03cad845625f6ae8e44cba1add522090212bf1c4607f51b234b375eda56054de')
build() {
cd "${srcdir}/tropy-${pkgver}"
npm clean-install --no-progress 2&> /dev/null
npm run rebuild -- --force --global-libvips
npm run build
}
package() {
install -dm755 "${pkgdir}/usr/lib/tropy"
install -dm755 "${pkgdir}/usr/share/applications"
install -dm755 "${pkgdir}/usr/share/icons"
install -dm755 "${pkgdir}/usr/share/mime"
install -dm755 "${pkgdir}/usr/share/metainfo"
install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
cd "${srcdir}"
install -Dm755 tropy.sh "${pkgdir}/usr/bin/tropy"
cd "tropy-${pkgver}/dist/Tropy-linux-x64"
install -m644 -t "${pkgdir}/usr/share/applications" \
org.tropy.Tropy.desktop
install -m644 -t "${pkgdir}/usr/share/metainfo" \
org.tropy.Tropy.metainfo.xml
cd resources
install -m644 -t "${pkgdir}/usr/lib/tropy/" app.asar
cp -r app.asar.unpacked "${pkgdir}/usr/lib/tropy"
find "${pkgdir}/usr/lib/tropy" -type d -print0 | \
xargs -I {} -0 chmod 755 "{}"
find "${pkgdir}/usr/lib/tropy" -type f -print0 | \
xargs -I {} -0 chmod 644 "{}"
cp -r mime "${pkgdir}/usr/share/"
cp -r icons "${pkgdir}/usr/share/"
find "${pkgdir}/usr/share" -type d -print0 | \
xargs -I {} -0 chmod 755 "{}"
find "${pkgdir}/usr/share" -type f -print0 | \
xargs -I {} -0 chmod 644 "{}"
cd app.asar.unpacked
install -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" \
LICENSE LICENSE.chromium.html LICENSE.third-party.txt
}
|