PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: aksr <aksr at t-com dot me>
# Maintainer: Caleb Maclennan <caleb@alerque.com>

pkgbase=ttf-crimson-pro-git
pkgname=("$pkgbase" "${pkgbase/ttf/otf}" "${pkgbase%-git}-variable-git")
_pkgname=CrimsonPro
pkgver=1.003.r11.g24e8f7b
pkgrel=1
pkgdesc='A professionally produced redesign of Crimson by Jacques Le Bailly'
arch=(any)
url="https://github.com/Fonthausen/$_pkgname"
license=(OFL)
makedepends=(git)
source=("$pkgbase::git+$url.git")
sha256sums=('SKIP')

pkgver() {
		cd "$pkgbase"
		# Upstream release commits are not always tagged, tag the last known release
		# manually here so the number of commits since the stable release is clear.
		git tag | grep -Fq '1.003' || git tag '1.003' cdd326e
		git describe --long --tags --abbrev=7 --match='[0-9]*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

package_otf-crimson-pro-git () {
		pkgdesc+=" (8 fixed weights)"
		provides=("${pkgname%-git}=$pkgver")
		conflicts=("${pkgname%-git}")
		cd "$pkgbase"
		install -Dm644 -t "$pkgdir/usr/share/fonts/OTF/" "fonts/otf/$_pkgname"*.otf
		install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" {OFL,AUTHORS,CONTRIBUTORS}.txt
}

package_ttf-crimson-pro-git () {
		pkgdesc+=" (8 fixed weights)"
		provides=("${pkgname%-git}=$pkgver")
		conflicts=("${pkgname%-git}")
		cd "$pkgbase"
		install -Dm644 -t "$pkgdir/usr/share/fonts/TTF/" "fonts/ttf/$_pkgname"*.ttf
		install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" {OFL,AUTHORS,CONTRIBUTORS}.txt
}

package_ttf-crimson-pro-variable-git () {
		pkgdesc+=" (variable weight)"
		provides=("${pkgname%-git}=$pkgver")
		conflicts=("${pkgname%-git}")
		cd "$pkgbase"
		install -Dm644 -t "$pkgdir/usr/share/fonts/TTF/" "fonts/variable/$_pkgname"*.ttf
		install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" {OFL,AUTHORS,CONTRIBUTORS}.txt
}