blob: 0ff9f80f863303c1dc47f286b594b9dd15f7bd32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=tui-slides
pkgver=0.1.4
pkgrel=1
pkgdesc="Terminal presentation utility with a modern TUI"
arch=('x86_64')
url="https://github.com/Chleba/tui-slides"
license=('Apache-2.0')
depends=('gcc-libs')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('bf9faf4dbfbc59472f140116591c564a178df20cbf52c0dfc9c3d5852ec716589d255b2d0e791decec15a0ca52d8808bbaaa975b9a04502e99b67327e2ebaecf')
options=('!lto')
prepare() {
cd "$pkgname-$pkgver"
cargo fetch --target "$(rustc -vV | sed -n 's/host: //p')" --locked
}
build() {
cd "$pkgname-$pkgver"
cargo build --release --frozen
}
check() {
cd "$pkgname-$pkgver"
cargo test --frozen
}
package() {
cd "$pkgname-$pkgver"
install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
}
|