PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

# Maintainer: Jeremy Gust <jeremy AT plasticsoup DOT net>
# Contributor: Angel de Vicente <angel.de.vicente at iac dot es>
# Contributor: Hyacinthe Cartiaux <hyacinthe.cartiaux at free.fr>
# Contributor: kfgz <kfgz at interia pl>
# Contributor: Kaspar Bumke <kaspar dot bumke at gmail dot com>
# Contributor: maleadt <tim dot besard at gmail dot com>
pkgname="turbovnc"
pkgdesc="A derivative of Virtual Network Computing that is tuned to provide peak performance for 3D and video workloads"
pkgver=3.1.3
pkgrel=2
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
url="http://www.turbovnc.org/"
license=('GPL-2.0-or-later')
depends=('bash'
         'glibc'
         'hicolor-icon-theme'
         'java-runtime>11'
         'libglvnd'
         'libjpeg-turbo'
         'libx11'
         'libxau'
         'libxdmcp'
         'libxext'
         'libxfont2'
         'libxi'
         'openssl'
         'pam'
         'perl'
         'pixman'
         'python'
         'zlib')
makedepends=('cmake>=3.12'
             'java-environment>11'
             'libxaw'
             'libxcursor'
             'libxt'
             'xorg-server'
             'xtrans')
conflicts=('tigervnc' 'tigervnc-git' 'tightvnc' 'tightvnc-git')
backup=(etc/turbovnc/turbovncserver.conf
        etc/turbovnc/turbovncserver-security.conf)
source=("https://github.com/TurboVNC/turbovnc/releases/download/$pkgver/$pkgname-$pkgver.tar.gz"{,.sig})
sha256sums=('fa5df2691ad0755cec790f631727791abfec7a35684b2ae23283e4ae4376adae'
            'ee7aff6aa7904b5f928cb42ff967c234c056d4265193992fd011ab32f7a61058')
validpgpkeys=(AE1A7BA4EFFF9A9987E1474C4BACCAB36E7FE9A1) # The VirtualGL Project <information@VirtualGL.org>

build() {
	export JAVA_HOME=/usr/lib/jvm/default/
	cmake -B build \
	      -S "$pkgname-$pkgver" \
	      -DCMAKE_BUILD_TYPE='None' \
	      -DCMAKE_INSTALL_PREFIX=/usr \
	      -DCMAKE_INSTALL_DOCDIR=/usr/share/doc/$pkgname \
	      -DCMAKE_INSTALL_MANDIR=/usr/share/man/$pkgname \
	      -DCMAKE_INSTALL_SYSCONFDIR=/etc/turbovnc \
	      -Wno-dev \
	      -G "Unix Makefiles" \
	      -DTJPEG_LIBRARY=/usr/lib/libturbojpeg.so \
	      -DTVNC_SYSTEMLIBS=1 \
	      -DTVNC_SYSTEMX11=1
	cmake --build build
}

package() {
	cd build
	make DESTDIR="${pkgdir}" install
	rm -f "${pkgdir}/usr/share/man/man1/Xserver.1"
	rm -r "${pkgdir}/etc/turbovnc/init.d"
	printf "[Desktop Entry]\nName=TurboVNC Viewer\nComment=TurboVNC client application\n\
Exec=/usr/bin/vncviewer\nTerminal=false\nIcon=turbovnc\nType=Application\n\
Categories=Application;Utility;\n" >> tvncviewer.desktop
	install -Dm755 tvncviewer.desktop "${pkgdir}/usr/share/applications/tvncviewer.desktop"
}