blob: 4859a6e886e70c8ee913d58798e4c81b667bf92c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Co-Maintainer: Aaron J. Graves <linux@ajgraves.com>
# Contributor: ganthern <https://github.com/ganthern>
pkgname=tutanota-desktop
pkgver=244.240913.1
pkgrel=1
pkgdesc="Official Tutanota email client"
arch=('x86_64')
url="https://tuta.com"
license=('GPL-3.0-or-later')
depends=('alsa-lib' 'gtk3' 'libsecret' 'nss')
makedepends=('emscripten' 'git' 'nvm' 'python')
source=("git+https://github.com/tutao/tutanota.git#tag=$pkgname-release-$pkgver"
'git+https://github.com/P-H-C/phc-winner-argon2.git'
'git+https://github.com/open-quantum-safe/liboqs.git'
"$pkgname.desktop")
sha256sums=('b3dcc65405db9750b089a87f2c66fdd9b1dc3e7222c5085957d3a7e6651a5fa9'
'SKIP'
'SKIP'
'd6fef99f41fe18008e44b5930aee26dc2f79ef753d770cbdb946d9e17ac9b7d7')
_ensure_local_nvm() {
# let's be sure we are starting clean
which nvm >/dev/null 2>&1 && nvm deactivate && nvm unload
export NVM_DIR="${srcdir}/.nvm"
# The init script returns 3 if version specified
# in ./.nvrc is not (yet) installed in $NVM_DIR
# but nvm itself still gets loaded ok
source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
}
prepare() {
cd "${pkgname%-*}"
git submodule init
git config submodule.libs/webassembly/phc-winner-argon2.url "$srcdir/phc-winner-argon2"
git config submodule.libs/webassembly/liboqs.url "$srcdir/liboqs"
git -c protocol.file.allow=always submodule update
_ensure_local_nvm
nvm install
}
build() {
cd "${pkgname%-*}"
export npm_config_cache="$srcdir/npm_cache"
_ensure_local_nvm
npm ci
npm run build-packages
node desktop --custom-desktop-release --unpacked
}
package() {
cd "${pkgname%-*}"
install -d "$pkgdir/opt/$pkgname/"
cp -av artifacts/desktop/linux-unpacked/* "$pkgdir/opt/$pkgname/"
chmod 4755 "$pkgdir/opt/$pkgname/chrome-sandbox"
install -d "$pkgdir/usr/bin"
ln -s "/opt/$pkgname/$pkgname" "$pkgdir/usr/bin/"
for i in 16 32 48 64 128 256 512; do
install -Dm644 resources/desktop-icons/logo-solo-red.png.iconset/icon_${i}x${i}.png \
"$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/$pkgname.png"
install -Dm644 resources/desktop-icons/logo-solo-red.png.iconset/icon_${i}x${i}@2x.png \
"$pkgdir/usr/share/icons/hicolor/${i}x${i}@2x/apps/$pkgname.png"
done
install -Dm644 "$srcdir/$pkgname.desktop" -t "$pkgdir/usr/share/applications/"
}
|