blob: dbde0e5ad1bef27c3db8c2b564ec2cf4cd0f49e0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Contributor: Nguyễn Quang Minh <minhnbnt at gmail dot com>
pkgname=ty-bin
pkgver=0.0.1-alpha.16 # datasource=github-tags depName=astral-sh/ty
pkgver="${pkgver//-/_}"
pkgrel=1
pkgdesc='An extremely fast Python type checker and language server, written in Rust.'
arch=('aarch64' 'armv7' 'i686' 'x86_64')
url='https://github.com/astral-sh/ty'
depends=('glibc' 'gcc-libs')
license=('MIT')
provides=('ty')
conflicts=('ty')
_baseurl="${url}/releases/download/${pkgver//_/-}"
source_aarch64=("ty-aarch64-${pkgver}.tgz::${_baseurl}/ty-aarch64-unknown-linux-gnu.tar.gz")
source_armv7=("ty-armv7-${pkgver}.tgz::${_baseurl}/ty-armv7-unknown-linux-gnueabihf.tar.gz")
source_i686=("ty-i686-${pkgver}.tgz::${_baseurl}/ty-i686-unknown-linux-gnu.tar.gz")
source_x86_64=("ty-x86_64-${pkgver}.tgz::${_baseurl}/ty-x86_64-unknown-linux-gnu.tar.gz")
source=("LICENSE-${pkgver}::${url}/raw/refs/tags/${pkgver//_/-}/LICENSE")
sha256sums=('860e3d7a86b84e6a7012c7a635fc64df475cebc6cce34dfeb73a5982ec58176c')
sha256sums_aarch64=('14fc2e26635f53eaf65765a22ba4498b1188131e54082675169b7c8625c23fdf')
sha256sums_armv7=('3988b261deba3870879ee5af3d3c520c21e53c44827bde0754a156a6169b73ce')
sha256sums_i686=('ac1368a67a32d5f4e8f451c272fd85c8db3dc379d9bbf24444b2b1e076818c15')
sha256sums_x86_64=('8444da3c0a08176694eb02b2843b519ce4bf22c5f7095012f85e855a124a001a')
package() {
local target="${pkgdir}/usr/bin/ty"
install -Dm755 "ty-${CARCH}-unknown-linux-gnu/ty" "$target"
install -Dm644 "LICENSE-${pkgver}" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
$target generate-shell-completion bash | \
install -Dm0644 /dev/stdin "$pkgdir/usr/share/bash-completion/completions/$pkgbase.bash"
$target generate-shell-completion elvish | \
install -Dm0644 /dev/stdin "$pkgdir/usr/share/elvish/lib/$pkgbase.elv"
$target generate-shell-completion fish | \
install -Dm0644 /dev/stdin "$pkgdir/usr/share/fish/vendor_completions.d/$pkgbase.fish"
$target generate-shell-completion zsh | \
install -Dm0644 /dev/stdin "$pkgdir/usr/share/zsh/site-functions/_$pkgbase"
}
|