PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=unixodbc-git
pkgver=2.3.12.r12.g9b31cd2
pkgrel=1
pkgdesc="An open specification for providing application developers with a predictable API with which to access Data Sources"
arch=('i686' 'x86_64')
url="https://www.unixodbc.org/"
license=('LGPL')
depends=('glibc' 'libltdl' 'readline')
makedepends=('git')
provides=("unixodbc=$pkgver")
conflicts=('unixodbc')
backup=(etc/odbc{,inst}.ini)
options=('staticlibs')
source=("git+https://github.com/lurcher/unixODBC.git")
sha256sums=('SKIP')


pkgver() {
  cd "unixODBC"

  _tag=$(git tag -l --sort -creatordate | grep -E '^v?[0-9\.]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "unixODBC"

  autoreconf -fi
  ./configure \
    --prefix="/usr" \
    --sysconfdir="/etc" \
    --enable-static
  make
}

check() {
  cd "unixODBC"

  make check
}

package() {
  cd "unixODBC"

  make DESTDIR="$pkgdir" install
}