blob: 00851ca4d8c85730ef66e261df6c81a00c36e2a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
|
# Maintainer: Viech <viech unvanquished net>
# Contributor: Gereon Schomber
# Contributor: Martin F. Schumann
pkgname=unvanquished
pkgver=0.54.1
pkgrel=1
pkgdesc='A team-based, fast-paced, fps/rts hybrid game which pits aliens against humans.'
arch=('x86_64' 'aarch64')
url='https://www.unvanquished.net'
license=('GPL3')
makedepends=('cmake')
depends=("unvanquished-data>=${pkgver}"
'zlib' 'gmp' 'nettle' 'geoip' 'curl' 'sdl2' 'glew' 'libpng'
'libjpeg-turbo' 'libwebp>=0.2.0' 'freetype2' 'openal' 'libogg'
'libvorbis' 'speex' 'libtheora' 'opusfile' 'ncurses' 'xdg-utils'
'desktop-file-utils' 'shared-mime-info' 'hicolor-icon-theme')
provides=('unvanquished')
conflicts=('unvanquished-git')
options=('emptydirs' '!strip')
backup=('etc/conf.d/unvanquished.conf'
'etc/unvanquished/server.cfg'
'etc/unvanquished/maprotation.cfg')
install=unvanquished.install
# Shorthand strings.
_archive="archive/refs/tags/unvanquished/${pkgver}.tar.gz"
_suffix="unvanquished-${pkgver}"
_unvanquished="Unvanquished-${_suffix}"
_daemon="Daemon-${_suffix}"
_breakpad="breakpad-${_suffix}"
_crunch="crunch-${_suffix}"
_recast="recastnavigation-${_suffix}"
# NaCL SDK is a buildtime dependency of Dæmon.
# NOTE: Due to enormous compile times, we use a binary distribution.
_naclsdk_base_ver=6
_naclsdk_ver="linux64-${_naclsdk_base_ver}"
_naclsdk="${_naclsdk_ver}"
source=("unvanquished.install"
"unvanquished.sh"
"unvanquished-tty.sh"
"unvanquished.conf"
"unvanquished.desktop"
"unvanquished.service"
"unvanquished_${pkgver}.tar.gz::https://github.com/Unvanquished/Unvanquished/${_archive}"
"daemon_${pkgver}.tar.gz::https://github.com/DaemonEngine/Daemon/${_archive}"
"breakpad_${pkgver}.tar.gz::https://github.com/DaemonEngine/breakpad/${_archive}"
"crunch_${pkgver}.tar.gz::https://github.com/DaemonEngine/crunch/${_archive}"
"recastnavigation_${pkgver}.tar.gz::https://github.com/DaemonEngine/recastnavigation/${_archive}"
"naclsdk_${_naclsdk_ver}.tar.bz2::https://dl.unvanquished.net/deps/${_naclsdk_ver}.tar.bz2")
md5sums=('6d9430b5b06b93a43a1cb79e14637f0b'
'8d89d015e13f39f1849dfa40146dbfb6'
'705d8ad238356cd8fc97f63060f9b2e9'
'fd69458c8aa7fa8e71cea6a5993fdcbc'
'b3c672d4dae710f9049389e422c8ba65'
'acf733d3389af8806edc54c872212e53'
'4f7d88a6444772ff0e7f9856c1372df7'
'0e9dad7ed07df4362ea3ca24aac2d967'
'c18e3b35b02838acb1cc188e91aa9561'
'c1c2fc7ed403b59ecaa6e2e80c42c6cd'
'201c1787017deae864017e123360eaec'
'8e3e08ca8797e45e8dc01cdadf938676')
# The prepare function mimics the git submodule dance.
prepare() {
cd "${srcdir}"
# From Unvanquished: Remove empty submodule directories.
rmdir --ignore-fail-on-non-empty "${_unvanquished}/daemon"
rmdir --ignore-fail-on-non-empty "${_unvanquished}/libs/recastnavigation"
# From Dæmon: Remove empty submodule directories.
rmdir --ignore-fail-on-non-empty "${_daemon}/libs/breakpad"
rmdir --ignore-fail-on-non-empty "${_daemon}/libs/crunch"
# Link Unvanquished's submodules.
ln -sfr "${_daemon}" "${_unvanquished}/daemon"
ln -sfr "${_recast}" "${_unvanquished}/libs/recastnavigation"
# Link Dæmon's submodules.
ln -sfr "${_breakpad}" "${_daemon}/libs/breakpad"
ln -sfr "${_crunch}" "${_daemon}/libs/crunch"
# Link the NaCL SDK in the Dæmon source tree.
ln -sfr "${_naclsdk}" "${_daemon}/external_deps/${_naclsdk}"
# Work around a compilation failure.
sed -i '/#include "common\/using_std_string.h"/a #include <cstring>' \
"./breakpad-${_suffix}/src/client/linux/handler/minidump_descriptor.h"
sed -i '/#include <cstring>/a #include <cstdint>' \
"./breakpad-${_suffix}/src/client/linux/handler/minidump_descriptor.h"
}
build() {
cd "${srcdir}/${_unvanquished}"
mkdir -p build
cd build
cmake \
-D BUILD_CGAME=OFF \
-D BUILD_SGAME=OFF \
-D USE_BREAKPAD=ON \
..
make
}
package() {
cd "${pkgdir}"
# Create installation directories.
install -d -m 755 \
etc/conf.d \
etc/unvanquished \
usr/bin \
usr/lib/systemd/system \
usr/lib/unvanquished \
usr/share/applications \
usr/share/licenses/unvanquished \
usr/share/unvanquished/pkg \
var/lib/unvanquished-server/config \
var/lib/unvanquished-server/game
# Install content.
cd "${srcdir}"
install -m 755 unvanquished.sh "${pkgdir}/usr/bin/unvanquished"
install -m 755 unvanquished-tty.sh "${pkgdir}/usr/bin/unvanquished-tty"
install -m 644 unvanquished.conf "${pkgdir}/etc/conf.d/"
install -m 644 unvanquished.service "${pkgdir}/usr/lib/systemd/system/"
install -m 644 unvanquished.desktop "${pkgdir}/usr/share/applications/"
cd "${srcdir}/${_unvanquished}"
install -m 644 COPYING.txt "${pkgdir}/usr/share/licenses/unvanquished/"
cd "${srcdir}/${_unvanquished}/build"
install -m 755 daemon "${pkgdir}/usr/lib/unvanquished/"
install -m 755 daemonded "${pkgdir}/usr/lib/unvanquished/"
install -m 755 daemon-tty "${pkgdir}/usr/lib/unvanquished/"
install -m 755 crash_server "${pkgdir}/usr/lib/unvanquished/"
install -m 755 irt_core-*.nexe "${pkgdir}/usr/lib/unvanquished/"
install -m 755 nacl_helper_bootstrap "${pkgdir}/usr/lib/unvanquished/"
install -m 755 nacl_loader "${pkgdir}/usr/lib/unvanquished/"
if [ "${CARCH}" == "aarch64" ]; then
armlibdir="${pkgdir}/usr/lib/unvanquished/lib-armhf"
install -d -m 755 "${armlibdir}"
install -m 755 nacl_helper_bootstrap-armhf "${pkgdir}/usr/lib/unvanquished/"
install -m 755 lib-armhf/ld-linux-armhf "${armlibdir}"
install -m 755 lib-armhf/lib*.so.* "${armlibdir}"
fi
cd "${srcdir}/${_unvanquished}/dist/configs"
install -m 644 game/maprotation.cfg "${pkgdir}/etc/unvanquished/"
install -m 644 config/server.cfg "${pkgdir}/etc/unvanquished/"
cd "${srcdir}/${_unvanquished}/dist/icons"
for resolution in $(ls -c1); do
icondir="${pkgdir}/usr/share/icons/hicolor/${resolution}/apps"
install -d -m 755 "${icondir}"
install -m 644 "${resolution}/unvanquished.png" "${icondir}"
done
# setup server home directory
cd "${pkgdir}/var/lib/unvanquished-server/config"
ln -s ../../../../etc/unvanquished/server.cfg .
cd "${pkgdir}/var/lib/unvanquished-server/game"
ln -s ../../../../etc/unvanquished/maprotation.cfg .
}
|