summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 55f700dad8f199638e2f5c349e71f80886135646 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
# Contributor: Lex Black <autumn-wind@web.de>
# Contributor: xerc <aur[at]xerc.de>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: milomouse <vincent[at]fea.st>
# Contributor: judd <jvinet@zeroflux.org>

_basename=util-linux
pkgbase=util-linux-aes
pkgname=(util-linux-aes util-linux-libs-aes)
_pkgmajor=2.38
_realver=${_pkgmajor}.1
pkgver=${_realver/-/}
pkgrel=1
pkgdesc='Miscellaneous system utilities for Linux, with loop-AES support'
url='https://github.com/karelzak/util-linux'
#url="http://sourceforge.net/projects/loop-aes/"
arch=('x86_64')
makedepends=('asciidoctor' 'libcap-ng' 'libxcrypt' 'python' 'systemd' 'gtk-doc')
license=('GPL2')
options=('strip')
install=${pkgname}.install
validpgpkeys=('B0C64D14301CC6EFAEDF60E4E4B71D5EEC39C284'  # Karel Zak
              '12D64C3ADCDA0AA427BDACDFF0733C808132F189') # Jari Ruusu
source=("https://www.kernel.org/pub/linux/utils/util-linux/v${_pkgmajor}/${_basename}-${_realver}.tar."{xz,sign}
        "${_basename}-${pkgver}.diff"
        pam-{login,common,runuser,su}
        'util-linux-aes.sysusers'
        '60-rfkill.rules'
        'rfkill-unblock_.service'
        'rfkill-block_.service')
sha256sums=('60492a19b44e6cf9a3ddff68325b333b8b52b6c59ce3ebd6a0ecaa4c5117e84f'
            'SKIP'
            '58238cf5bcacd1a5a0717cd5d1f3fccb74e6192e20b58f8282169bc80d518a8e'
            '99cd77f21ee44a0c5e57b0f3670f711a00496f198fc5704d7e44f5d817c81a0f'
            '57e057758944f4557762c6def939410c04ca5803cbdd2bfa2153ce47ffe7a4af'
            '48d6fba767631e3dd3620cf02a71a74c5d65a525d4c4ce4b5a0b7d9f41ebfea1'
            '3f54249ac2db44945d6d12ec728dcd0d69af0735787a8b078eacd2c67e38155b'
            '10b0505351263a099163c0d928132706e501dd0a008dac2835b052167b14abe3'
            '7423aaaa09fee7f47baa83df9ea6fef525ff9aec395c8cbd9fe848ceb2643f37'
            '8ccec10a22523f6b9d55e0d6cbf91905a39881446710aa083e935e8073323376'
            'a22e0a037e702170c7d88460cc9c9c2ab1d3e5c54a6985cd4a164ea7beff1b36')

prepare() {
  cd "$_basename-$pkgver"

  patch -Np1 -i "../${_basename}-${pkgver}.diff"
  autoreconf -i
}

build() {
  cd "${_basename}-${_realver}"

  ./configure \
    --prefix=/usr \
    --libdir=/usr/lib \
    --bindir=/usr/bin \
    --sbindir=/usr/bin \
    --localstatedir=/var \
    --enable-usrdir-path \
    --enable-fs-paths-default=/usr/bin:/usr/local/bin \
    --enable-vipw \
    --enable-newgrp \
    --enable-chfn-chsh \
    --enable-write \
    --enable-mesg \
    --with-python=3

  make
}

package_util-linux-aes() {
  conflicts=('rfkill' 'hardlink' "${_basename}")
  provides=('rfkill' 'hardlink' "${_basename}=2.38")
  replaces=('rfkill' 'hardlink')
  depends=('pam' 'shadow' 'coreutils' 'systemd-libs' 'libsystemd.so'
           'libudev.so' 'libcap-ng' 'libxcrypt' 'libcrypt.so' 'util-linux-libs-aes'
           'libmagic.so' 'libncursesw.so')
  optdepends=('python: python bindings to libmount'
              'words: default dictionary for look')
  backup=(etc/pam.d/chfn
          etc/pam.d/chsh
          etc/pam.d/login
          etc/pam.d/runuser
          etc/pam.d/runuser-l
          etc/pam.d/su
          etc/pam.d/su-l)

  cd "${_basename}-${_realver}"

  make DESTDIR="${pkgdir}" install

  # setuid chfn and chsh
  chmod 4755 "${pkgdir}"/usr/bin/{newgrp,ch{sh,fn}}

  # install PAM files for login-utils
  install -Dm0644 "${srcdir}/pam-common" "${pkgdir}/etc/pam.d/chfn"
  install -m0644 "${srcdir}/pam-common" "${pkgdir}/etc/pam.d/chsh"
  install -m0644 "${srcdir}/pam-login" "${pkgdir}/etc/pam.d/login"
  install -m0644 "${srcdir}/pam-runuser" "${pkgdir}/etc/pam.d/runuser"
  install -m0644 "${srcdir}/pam-runuser" "${pkgdir}/etc/pam.d/runuser-l"
  install -m0644 "${srcdir}/pam-su" "${pkgdir}/etc/pam.d/su"
  install -m0644 "${srcdir}/pam-su" "${pkgdir}/etc/pam.d/su-l"

  # TODO(dreisner): offer this upstream?
  sed -i '/ListenStream/ aRuntimeDirectory=uuidd' "${pkgdir}/usr/lib/systemd/system/uuidd.socket"

  # adjust for usrmove
  # TODO(dreisner): fix configure.ac upstream so that this isn't needed
  cd "${pkgdir}"
  mv usr/sbin/* usr/bin
  rmdir usr/sbin

  ### runtime libs are shipped as part of util-linux-libs
  rm "${pkgdir}"/usr/lib/lib*.{a,so}*

  ### install systemd-sysusers
  install -Dm0644 "${srcdir}/util-linux-aes.sysusers" \
    "${pkgdir}/usr/lib/sysusers.d/util-linux-aes.conf"

  install -Dm0644 "${srcdir}/60-rfkill.rules" \
    "${pkgdir}/usr/lib/udev/rules.d/60-rfkill.rules"

  install -Dm0644 "${srcdir}/rfkill-unblock_.service" \
    "${pkgdir}/usr/lib/systemd/system/rfkill-unblock@.service"
  install -Dm0644 "${srcdir}/rfkill-block_.service" \
    "${pkgdir}/usr/lib/systemd/system/rfkill-block@.service"
}

package_util-linux-libs-aes() {
  pkgdesc="util-linux runtime libraries"
  provides=('libutil-linux' 'libblkid.so' 'libfdisk.so' 'libmount.so' 'libsmartcols.so' 'libuuid.so' "${_basename}-libs=2.38")
  conflicts=('libutil-linux' "${_basename}-libs")
  replaces=('libutil-linux')

  make -C "${_basename}-${_realver}" DESTDIR="${pkgdir}" install-usrlib_execLTLIBRARIES
}