blob: 640dfb4c3adfa9e0c60a385739b2a4b94e592323 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
_plug=fieldhint
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=3.1.g1e78532
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('x86_64')
url="https://github.com/dubhater/vapoursynth-${_plug}"
license=('GPL')
depends=('vapoursynth')
makedepends=('git')
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/dubhater/vapoursynth-${_plug}.git")
sha256sums=('SKIP')
options=('debug')
pkgver() {
cd "${_plug}"
echo "$(git describe --long --tags | tr - . | tr -d v)"
}
prepare() {
mkdir -p build
}
build() {
cd "${_plug}"
./autogen.sh
cd "${srcdir}/build"
"../${_plug}/configure" \
--prefix=/usr \
--libdir=/usr/lib/vapoursynth
make
}
package(){
make -C build DESTDIR="${pkgdir}" install
install -Dm644 "${_plug}/readme.rst" "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/readme.rst"
}
|