blob: b16ea8eef3a720089e03b98b17f0f2a3433266e3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
_plug=nnedi3cl
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=8.0.geb2a810
pkgrel=2
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('x86_64')
url='https://github.com/HomeOfVapourSynthEvolution/VapourSynth-NNEDI3CL'
license=('GPL2')
depends=('vapoursynth'
'vapoursynth-plugin-nnedi3_weights_bin'
'opencl-icd-loader'
'libboost_filesystem.so'
)
makedepends=('git'
'opencl-headers'
'boost'
'meson'
)
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/HomeOfVapourSynthEvolution/VapourSynth-NNEDI3CL.git")
sha256sums=('SKIP')
options=('debug')
pkgver() {
cd "${_plug}"
echo "$(git describe --long --tags | tr - . | tr -d r)"
}
prepare() {
mkdir -p build
cd "${_plug}"
sed 's/, meson.project_name()//g' \
-i meson.build
}
build() {
cd build
arch-meson "../${_plug}" \
--buildtype=release \
--libdir /usr/lib/vapoursynth \
--datadir /usr/lib/vapoursynth
ninja
}
package(){
DESTDIR="${pkgdir}" ninja -C build install
install -Dm644 "${_plug}/README.md" "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/README.md"
rm -fr "${pkgdir}/usr/lib/vapoursynth/NNEDI3CL"
}
|