blob: 13755910871aeef8e68e1ed421949cefd26a0cb2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: hybridkernel <admin@hzqki.me>
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>
_plug=vsakarin-llvm14
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=0.96f.2.g8b7ff6d
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('x86_64')
url='https://github.com/akarinVS/vapoursynth-plugin.git'
license=('GPL')
depends=(
'vapoursynth'
'gcc-libs' # libgcc_s.so libstdc++.so
'glibc' # ld-linux-x86-64.so libc.so libm.so
'llvm14-libs' # libLLVM-15.so
)
makedepends=(
'git'
'meson'
'llvm14'
)
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}" "vapoursynth-plugin-vsakarin-git")
source=("${_plug}::git+https://github.com/akarinVS/vapoursynth-plugin.git")
sha256sums=('SKIP')
options=('debug')
pkgver() {
cd "${_plug}"
echo "$(git describe --long --tags | tr - . | tr -d v)"
}
prepare() {
cat > native_config <<EOF
[binaries]
llvm-config = '/usr/lib/llvm14/bin/llvm-config'
EOF
}
build() {
arch-meson "${_plug}" build \
--buildtype=release \
--native-file=native_config \
-Dstatic-llvm=false
meson compile -C build
}
package() {
DESTDIR="${pkgdir}" meson install -C build
install -Dm644 "${_plug}/README.md" "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/README.md"
}
|