PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

_plug=vsdeband
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=1.2.0.1.gf947f90
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('any')
url='https://github.com/Irrational-Encoding-Wizardry/vs-deband'
license=('MIT')
depends=(
  'vapoursynth'
  'vapoursynth-plugin-vstools-git'
  'vapoursynth-plugin-vskernels-git'
  'vapoursynth-plugin-vsexprtools-git'
  'vapoursynth-plugin-vsrgtools-git'
  'vapoursynth-plugin-vsmasktools-git'
  'vapoursynth-plugin-vsaa-git'
  'vapoursynth-plugin-vsscale-git'
  'vapoursynth-plugin-vsdenoise-git'
)
makedepends=(
  'git'
  'python-build'
  'python-wheel'
  'python-installer'
  'python-setuptools'
)
optdepends=('vapoursynth-plugin-neo_f3kdb-git')
provides=("vapoursynth-plugin-${_plug}")
conflicts=(
  "vapoursynth-plugin-${_plug}"
  'vapoursynth-plugin-debandshit-git'
)
source=("${_plug}::git+https://github.com/Irrational-Encoding-Wizardry/vs-deband.git")
sha256sums=('SKIP')

pkgver() {
  cd "${_plug}"
  echo "$(git describe --long --tags | tr - . | tr -d v)"
}

build() {
  cd "${_plug}"
  python -m build --wheel --no-isolation
}

package() {
  cd "${_plug}"
  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 README.md "${pkgdir}/usr/share/doc/vapoursynth/tools/${_plug}/README.md"
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}