PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

_plug=vsmasktools
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=1.3.0.5.geb4bf7e
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('any')
url='https://github.com/Irrational-Encoding-Wizardry/vs-masktools'
license=('MIT')
depends=('vapoursynth-plugin-vstools-git'
    'vapoursynth-plugin-vskernels-git'
    'vapoursynth-plugin-vsexprtools-git'
    'vapoursynth-plugin-vsrgtools-git'
    'vapoursynth-plugin-tcanny-git'
    'vapoursynth-plugin-tedgemask-git'
    'vapoursynth-plugin-awarpsharp2-git'
    'vapoursynth-plugin-retinex-git'
    'vapoursynth-plugin-planestatsmod-git'
    'vapoursynth-plugin-vssource-git'
)
makedepends=('git'
    'python-pip'
    'python-wheel'
)
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/Irrational-Encoding-Wizardry/vs-masktools.git")
sha256sums=('SKIP')

pkgver() {
    cd "${_plug}"
    echo "$(git describe --long --tags | tr - . | tr -d v)"
}

build() {
    cd "${_plug}"
    pip wheel --no-deps . -w dist
}

package() {
    cd "${_plug}"
    pip install -I -U --root "${pkgdir}" --no-warn-script-location --no-deps dist/*.whl

    install -Dm644 README.md "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/README.md"
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}