PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer:  Gustavo Alvarez <sl1pkn07@gmail.com>

_plug=vstaambk
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=0.8.1.r118.9d0e19d
pkgrel=1
pkgdesc="Plugin for Vapoursynth: ${_plug} (GIT version)"
arch=('any')
url='https://github.com/HomeOfVapourSynthEvolution/vsTAAmbk'
license=('GPL')
depends=('vapoursynth-plugin-eedi2-git'
         'vapoursynth-plugin-nnedi3-git'
         'vapoursynth-plugin-eedi3m-git'
         'vapoursynth-plugin-mvtools'
         'vapoursynth-plugin-fmtconv-git'
         'vapoursynth-plugin-sangnom-git'
         'vapoursynth-plugin-tcanny-git'
         'vapoursynth-plugin-msmoosh-git'
         'vapoursynth-plugin-awarpsharp2-git'
         )
optdepends=('vapoursynth-plugin-nnedi3cl-git'
            'vapoursynth-plugin-znedi3-git'
            'vapoursynth-plugin-eedi2cuda-git'
            'vapoursynth-plugin-havsfunc-git'
            'vapoursynth-plugin-mvsfunc-git'
            )
makedepends=('git')
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/HomeOfVapourSynthEvolution/vsTAAmbk.git")
sha256sums=('SKIP')

_site_packages="$(python -c 'import sysconfig; print(sysconfig.get_paths()["purelib"])')"

pkgver() {
  cd "${_plug}"
  _ver="$(cat README.md | grep '# vsTAAmbk' | cut -d ' ' -f3)"
  echo "${_ver}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

package() {
  cd "${_plug}"
  install -Dm644 vsTAAmbk.py "${pkgdir}${_site_packages}/vsTAAmbk.py"
  python -m compileall -q -f -d "${_site_packages}" "${pkgdir}${_site_packages}/vsTAAmbk.py"
  python -OO -m compileall -q -f -d "${_site_packages}" "${pkgdir}${_site_packages}/vsTAAmbk.py"

  install -Dm644 README.md "${pkgdir}/usr/share/doc/vapoursynth/plugins/${_plug}/README.md"
}