blob: 32415daafb583b332c58d0b4b740108f7daf50f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: EinfxchFinn <finn.kuenstner@gmail.com>
pkgname=vesktop_electron
_pkgname=Vesktop
pkgdesc="Vesktop gives you the performance of web Discord and the comfort of Discord Desktop, using the system provided Electron"
pkgver=1.5.2
pkgrel=2
arch=('x86_64' 'aarch64')
url="https://github.com/Vencord/Vesktop"
license=('GPL3')
depends=('electron29')
makedepends=('pnpm' 'git')
optdepends=(
'libnotify: Notifications'
'xdg-utils: Open links, files, etc'
'xdg-desktop-portal: Screensharing with Wayland'
'arrpc: Rich presence support'
)
provides=('vesktop')
conflicts=('vesktop' 'vesktop-bin' 'vesktop-git')
source=("${url}/archive/refs/tags/v${pkgver}.tar.gz"
'vesktop.desktop'
'vesktop.sh')
sha256sums=('2795891c71d3ec39fd412cf1396a3172499b58619b2e7f92ce81de3db19d5de7'
'f279b1e469fb965cdf6dba9b4f428b0a7f28f414d84a47c6481b726adeb99c2b'
'e7f658771cc9fb6394b676f6ddf839f0641fe7fb9dc4f427ba8a619b7d0ce029')
prepare() {
# Accept any pnpm version
sed -i 's/"pnpm@.*/"pnpm@"\,/' "$srcdir/$_pkgname-$pkgver/package.json"
# Use system's electron
sed -i '/linux/s/^/ "electronDist": "\/usr\/lib\/electron29",\n/' "$srcdir/$_pkgname-$pkgver/package.json"
}
build() {
cd "$_pkgname-$pkgver"
pnpm i
pnpm package:dir
}
package() {
cd "$srcdir"
install -d "${pkgdir}/usr/lib/${pkgname}"
install -d "${pkgdir}/usr/bin"
cp "$_pkgname-$pkgver/dist/linux-unpacked/resources/app.asar" "${pkgdir}/usr/lib/${pkgname}/"
install -Dm755 "./vesktop.sh" "$pkgdir/usr/bin/vesktop"
install -Dm 644 "vesktop.desktop" "$pkgdir/usr/share/applications/vesktop.desktop"
install -Dm 644 "$_pkgname-$pkgver/static/icon.png" "$pkgdir/usr/share/pixmaps/vesktop.png"
install -Dm 644 "$_pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|