blob: d75e6ea5a63c5a94a56e3c4ed8ccbb8985f9ed77 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer:
# Contributor: Mark Wagie <mark dot wagie at proton dot me>
pkgname=vgrive
pkgver=1.6.1
pkgrel=6
pkgdesc="Google Drive client made in Vala"
arch=('x86_64')
url="https://github.com/bcedu/VGrive"
license=('GPL3')
depends=('gtk3' 'granite' 'libappindicator-gtk3' 'libsoup')
makedepends=('meson' 'vala' 'wayland-protocols')
checkdepends=('appstream-glib')
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz"
'https://github.com/bcedu/VGrive/pull/116.patch')
sha256sums=('f125ef74ce1d53517cc45d69716bb9668847d5c406096306aedf2a1178b4bfde'
'1210228c34d35b3b9464df735464c17124fa9d8bb693ccb708370a0bf8b14735')
prepare() {
cd "VGrive-$pkgver"
# Fix compilation errors in new vala
patch -Np1 -i "$srcdir/116.patch"
}
build() {
arch-meson "VGrive-$pkgver" build
meson compile -C build
}
check() {
meson test -C build --print-errorlogs || :
}
package() {
meson install -C build --destdir "$pkgdir"
ln -s /usr/bin/com.github.bcedu.vgrive "$pkgdir/usr/bin/$pkgname"
}
|