PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Frederic Bezies <fredbezies at gmail dot com>
# Based on vice-svn PKGBUILD by Benjamin Hodgetts <ben@xnode.org>

pkgname=vice-sdl2-svn
_pkgname=vice-svn
pkgver=r45439
pkgrel=1
pkgdesc="The Versatile Commodore Emulator 8-bits (PET/C64/C128/Plus4/Vic20) - SDL2 development version"
arch=('i686' 'x86_64')
url="http://vice-emu.sourceforge.net"
license=('GPL-2.0-or-later')
depends=(alsa-lib libpulse sdl2_image portaudio pciutils curl)
makedepends=(dos2unix libpcap libxaw texlive-bin  texlive-plaingeneric xa xorg-bdftopcf xorg-mkfontdir svn)
provides=('vice')
replaces=('vice')
conflicts=('vice' 'vice-svn')
source=("${_pkgname}::svn://svn.code.sf.net/p/vice-emu/code/trunk")
sha256sums=('SKIP')
options=(!debug)

pkgver() {
    echo r$(svnversion "${SRCDEST}"/${_pkgname}/)
}

build() {
    cd "${_pkgname}/vice"
       
    ./autogen.sh
    ./configure --prefix=/usr --libdir=/usr/lib --enable-sdl2ui --enable-pdf-docs --enable-ethernet --with-libcurl
    make
}

package() {
    cd "${_pkgname}/vice"
    make install DESTDIR="${pkgdir}/"
}