PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: Sematre <sematre at gmx dot de>
pkgname=videosubfinder
pkgver=6.10
pkgrel=1

pkgdesc="Audio/Video processing software with focus on new generation HD formats, Blu-ray and HD DVD."
arch=('x86_64')
url="https://sourceforge.net/projects/videosubfinder/"
license=('GPL2')

depends=('gtk3' 'wxwidgets-gtk3' 'opencv' 'ffmpeg4.4' 'tbb')
makedepends=('git' 'cmake' 'imagemagick')

source=("${pkgname}::git+https://git.code.sf.net/p/videosubfinder/src#tag=VideoSubFinder_${pkgver}"
        "videosubfinder.desktop"
        "start-videosubfinder.sh")
sha256sums=('SKIP'
            'b58e06818ca3314f0df91bd67edaa3bbce423cbd8b1160a23ef813585a95558c'
            'fb3f9e7d98494a185b56cc61e7488985adb8955f9e7aa797e40f51f6b7e5f91e')

build() {
	cd "${srcdir}"

	# Build without CUDA support
	cmake -B build -S "${pkgname}" \
			-DCMAKE_BUILD_TYPE=Release \
			-DUSE_CUDA=OFF \
			-DFFMPEG_INCLUDE_DIRS='/usr/include/ffmpeg4.4' \
			-DCMAKE_INSTALL_PREFIX='/usr/share'

	cmake --build build --config Release

	# Convert app icon from ico to png
	convert "${pkgname}/Interfaces/VideoSubFinderWXW/videosubfinder.ico" "build/${pkgname}.png"
}

package() {
	cd "${srcdir}"
	DESTDIR="${pkgdir}" cmake --install build

	# Install the start script
	install -Dm755 "start-videosubfinder.sh" "${pkgdir}/usr/bin/videosubfinder"
	ln -s "videosubfinder" "${pkgdir}/usr/bin/VideoSubFinderWXW"

	# Install project docs and assets
	mkdir -p "${pkgdir}/usr/share/doc"
	mv "${pkgdir}/usr/share/VideoSubFinder/Docs" "${pkgdir}/usr/share/doc/${pkgname}"

	install -Dm644 "build/${pkgname}-0.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
	install -Dm644 "${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"

	touch report.log
	install -Dm777 "report.log" -t "${pkgdir}/usr/share/VideoSubFinder"
}