blob: 9e40b704ff584f65fed96a16a5297e7f9bb8f81f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer:
pkgname=virtiofsd
pkgver=1.5.1
pkgrel=1
pkgdesc='A virtio-fs vhost-user device daemon written in Rust'
arch=('x86_64')
url='https://gitlab.com/virtio-fs/virtiofsd'
license=('Apache' 'BSD')
depends=('gcc-libs' 'libcap-ng' 'libseccomp')
makedepends=('git' 'rust')
options=('!lto')
_commit='e9d7275892abd49e838d0fa9a8805fed063f782d'
source=("$pkgname::git+$url.git#commit=$_commit")
b2sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/^v//'
}
prepare() {
cd "$pkgname"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$pkgname"
cargo build --frozen --release --all-features
}
check() {
cd "$pkgname"
cargo test --frozen --all-features
}
package() {
cd "$pkgname"
# binary
install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
# licenses
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE*
}
|