PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: ml <ml-aur@ransomware.download>
pkgname=vt-cli
_gitcommit=4ece259925ad5b08ea5883d595437e57ce2e3d6e
epoch=1
pkgver=1.0.1
pkgrel=2
pkgdesc='VirusTotal Command Line Interface'
arch=('i686' 'x86_64')
url=https://virustotal.github.io/vt-cli/
license=('Apache-2.0')
depends=('glibc')
makedepends=('git' 'go')
#source=("https://github.com/VirusTotal/vt-cli/archive/$pkgver/$pkgname-$pkgver.tar.gz")
source=("$pkgname"::git+https://github.com/VirusTotal/vt-cli#commit="${_gitcommit}")
sha256sums=('71a2a57a0c1b636710cde6f1de8025429c74fd089b51f9bc9544f69a6710127a')

build() {
    #cd "$pkgname-$pkgver"
    cd "$pkgname"
    export CGO_ENABLED=1
    export CGO_LDFLAGS="$LDFLAGS"
    export CGO_CFLAGS="$CFLAGS"
    export CGO_CPPFLAGS="$CPPFLAGS"
    export CGO_CXXFLAGS="$CXXFLAGS"
    export GOFLAGS='-buildmode=pie -trimpath -modcacherw'
    go build -o build/vt -ldflags "-linkmode=external -X github.com/VirusTotal/vt-cli/cmd.Version=$pkgver" ./vt
    build/vt completion bash >vt.bash
    build/vt completion zsh >vt.zsh
    build/vt completion fish >vt.fish
}

check() {
    cd "$pkgname"
    # yaml_test.go broken. fails upstream as well
    go test -ldflags "-linkmode=external" -short ./utils/...
}

package() {
    cd "$pkgname"
    install -Dm755 build/vt -t "$pkgdir/usr/bin"
    install -Dm644 vt.bash "$pkgdir/usr/share/bash-completion/completions/vt"
    install -Dm644 vt.zsh "$pkgdir/usr/share/zsh/site-functions/_vt"
    install -Dm644 vt.fish "$pkgdir/usr/share/fish/vendor_completions.d/$pkgname".fish
    install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" doc/*
}