blob: 71459a02176d93fd55c82b69ff3498a7ec73ebda (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Manuel Hüsers <manuel.huesers@uni-ol.de>
# Maintainer: Fernando Fernandez <fernando@softwareperonista.com.ar>
# Contributor: Ionut Biru <ibiru@archlinux.org>
pkgbase=vte3-notification
pkgname=(vte3-notification vte-notification-common)
pkgver=0.42.0
pkgrel=1
pkgdesc="Virtual Terminal Emulator widget for use with GTK3"
arch=('i686' 'x86_64')
license=('LGPL')
makedepends=('intltool' 'gobject-introspection' 'gtk3' 'vala' 'gperf')
url="http://www.gnome.org"
source=("https://download.gnome.org/sources/vte/${pkgver::4}/vte-${pkgver}.tar.xz"
'0001-widget-Only-show-the-cursor-on-motion-if-moved.patch'
'add-zsh-notfication-support.patch'
'vte291-command-notify.patch')
sha256sums=('2168f79d2043cbbe6d4375d01e54cebda71bb6f5d9dc8ad658b9a1dc1052de04'
'4379593bdddbe7ebcf6efd808f6334ce86334426d07f7ad777a3aa2d1ee2c50d'
'150a151404ca565f70259044661b2ef5cda43142ca677e7da324614eef8cf45a'
'd7dce79b0950b35052f60cacc7ce835a6111a4f3e833a5406590ff141fb41825')
prepare () {
cd "vte-${pkgver}"
patch -p1 -i ../0001-widget-Only-show-the-cursor-on-motion-if-moved.patch
patch -p1 -i ../vte291-command-notify.patch
patch -p1 -i ../add-zsh-notfication-support.patch
}
build() {
cd "vte-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc \
--libexecdir=/usr/lib/vte \
--localstatedir=/var --disable-static \
--enable-introspection --enable-gnome-pty-helper
make
}
package_vte3-notification(){
depends=('gtk3' 'vte-notification-common')
provides=("vte3=${pkgver}")
conflicts=('vte3')
options=('!emptydirs')
cd "vte-${pkgver}"
make DESTDIR="${pkgdir}" install
rm "${pkgdir}/etc/profile.d/vte.sh"
}
package_vte-notification-common() {
pkgdesc="Common files used by vte and vte3"
depends=('glibc')
provides=("vte-common=${pkgver}")
conflicts=('vte-common')
cd "vte-${pkgver}"
install -d "${pkgdir}/usr/lib/vte/gnome-pty-helper"
install -Dm644 src/vte.sh "${pkgdir}/etc/profile.d/vte.sh"
}
|