blob: a6fb6e4c2735745d436a4896f79b0daa74b73564 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Exorcism, AutoUpdateBot
# Contributor: envolution
# Contributor: hawkeye116477 <hawkeye116477 at gmail dot com>
# shellcheck shell=bash disable=SC2034,SC2154
pkgname=waterfox-bin
epoch=1
pkgver=6.6.17
pkgrel=1
pkgdesc="Current/modern generation of customizable privacy-conscious web browser."
arch=('x86_64')
url="https://www.waterfox.net"
license=('MPL-2.0')
depends=('gtk3' 'libxt' 'startup-notification' 'mime-types' 'dbus-glib' 'ffmpeg'
'ttf-font' 'hicolor-icon-theme')
optdepends=('networkmanager: Location detection via available WiFi networks'
'libnotify: Notification integration'
'pulseaudio: Audio support'
'alsa-lib: Audio support'
'speech-dispatcher: Text-to-Speech'
'hunspell-en_US: Spell checking, American English')
provides=("waterfox=${pkgver}")
source=("waterfox-${pkgver}-${pkgrel}.tar.bz2::https://cdn.waterfox.com/waterfox/releases/${pkgver}/Linux_x86_64/waterfox-${pkgver}.tar.bz2"
"waterfox.desktop")
conflicts=('waterfox')
package() {
# Create the necessary directories.
install -d "${pkgdir}"/{usr/{bin,share/applications},opt}
# Install the desktop files.
install -m644 "${srcdir}"/waterfox.desktop "${pkgdir}"/usr/share/applications/
# Copy the extracted directory to /opt/.
cp -r waterfox "${pkgdir}"/opt/waterfox
# Install icons
for i in 16 32 48 64 128; do
install -d "$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps"
ln -Ts /opt/waterfox/browser/chrome/icons/default/default$i.png \
"$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/waterfox.png"
done
# Add additional useful settings
install -Dm644 /dev/stdin "$pkgdir/opt/waterfox/browser/defaults/preferences/vendor.js" <<END
// Disable default browser checking
pref("browser.shell.checkDefaultBrowser", false);
// Use LANG environment variable to choose locale
pref("intl.locale.requested", "");
// Automatic installation of updates won't work on root, so disable this
pref("app.update.auto", false);
// Use system-provided dictionaries
pref("spellchecker.dictionary_path", "/usr/share/hunspell");
END
# Disable automatic updates and update notifications and allow only for manual update checking
install -Dm644 /dev/stdin "$pkgdir/opt/waterfox/distribution/policies.json" <<END
{
"policies": {
"AppAutoUpdate": false,
"ManualAppUpdateOnly": true
}
}
END
# Symlink the binary to /usr/bin/.
ln -s /opt/waterfox/waterfox "${pkgdir}"/usr/bin/waterfox
# Backward compatibility symlink
ln -s /opt/waterfox/waterfox "${pkgdir}"/usr/bin/waterfox-g
}
sha512sums=('580e88f93995e315eb8d514c596b3f55f047451a630ece854ed1a6b9c9d787465ef8bc20475f9f9c36a6b71f1b8fafbd8929fe3b25af433b44ef8e8365fe9c6f'
'd0237cffceb1f22bcef3479ee192360c069052534cbe6f452bf88e671ba26b7d8d04f6cdbb4f34647277b64136093d703b5f9ac8071fe0d3c80d70b1e1395a84')
# vim:set ts=2 sw=2 et:
|