blob: 9153f1355cd7b8836cab49a002f3741cdc9588c5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: hawkeye116477 <hawkeye116477 at gmail dot com>
pkgname=waterfox-g4-bin
pkgver=1.5
pkgrel=0
pkgdesc="Fourth generation of customizable privacy-conscious web browser."
arch=('x86_64')
url="https://www.waterfox.net"
license=('MPL')
depends=('gtk3' 'gtk2' 'libxt' 'startup-notification' 'mime-types' 'dbus-glib' 'ffmpeg'
'ttf-font' 'hicolor-icon-theme')
optdepends=('networkmanager: Location detection via available WiFi networks'
'libnotify: Notification integration'
'pulseaudio: Audio support'
'alsa-lib: Audio support'
'speech-dispatcher: Text-to-Speech'
'hunspell-en_US: Spell checking, American English')
provides=("waterfox-g4=${pkgver}")
conflicts=('waterfox-g4')
source=('waterfox-g4.desktop'
'https://github.com/WaterfoxCo/Waterfox/releases/download/G4.'"${pkgver}"'/waterfox-G4.'"${pkgver}"'.en-US.linux-x86_64.tar.bz2')
package() {
# Create the necessary directories.
install -d "${pkgdir}"/{usr/{bin,share/applications},opt}
# Install the desktop files.
install -m644 "${srcdir}"/waterfox-g4.desktop "${pkgdir}"/usr/share/applications/
# Copy the extracted directory to /opt/.
cp -r waterfox "${pkgdir}"/opt/waterfox-g4
# Install icons
for i in 16 32 48 64 128; do
install -d "$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps"
ln -Ts /opt/waterfox-g4/browser/chrome/icons/default/default$i.png \
"$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/waterfox-g4.png"
done
# Add additional useful settings
install -Dm644 /dev/stdin "$pkgdir/opt/waterfox-g4/browser/defaults/preferences/vendor.js" <<END
// Disable default browser checking
pref("browser.shell.checkDefaultBrowser", false);
// Use LANG environment variable to choose locale
pref("intl.locale.requested", "");
// Automatic installation of updates won't work on root, so disable this
pref("app.update.auto", false);
// Use system-provided dictionaries
pref("spellchecker.dictionary_path", "/usr/share/hunspell");
END
# Disable automatic updates and update notifications and allow only for manual update checking
install -Dm644 /dev/stdin "$pkgdir/opt/waterfox-g4/distribution/policies.json" <<END
{
"policies": {
"AppAutoUpdate": false,
"ManualAppUpdateOnly": true
}
}
END
# Symlink the binary to /usr/bin/.
ln -s /opt/waterfox-g4/waterfox "${pkgdir}"/usr/bin/waterfox-g4
}
sha256sums=('76fde87eda671338d58a29d78ab081ca47aac2cde8faccafa646b0546b22bcfb'
'13f3c584a90c50ad0fe9006d1fe0906edfdaa02ced99f0f027090d226ed0f942')
|