blob: 44bea65fd23ac5ca76bd4d9759402f5b8eca1c32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
pkgname=webgal-terre-bin
_appname=WebGAL_Terre
pkgver=4.5.0
pkgrel=1
pkgdesc="Galgame Editing. Redefined | 视觉小说编辑,再进化"
arch=(
"aarch64"
"x86_64"
)
url="https://docs.openwebgal.com/guide/"
_ghurl="https://github.com/MakinoharaShoko/WebGAL_Terre"
license=('MPL-2.0')
provides=("${pkgname%-bin}=${pkgver}")
conflicts=("${pkgname%-bin}")
depends=(
'nspr'
'nss'
'libxext'
'java-runtime'
'alsa-lib'
'gtk3'
)
makedepends=(
'gendesk'
)
options=(
'!strip'
)
source_aarch64=("${pkgname%-bin}-${pkgver}-aarch64.zip::${_ghurl}/releases/download/${pkgver}/${_appname}_Linux_Arm64_${pkgver}.zip")
source_x86_64=("${pkgname%-bin}-${pkgver}-x86_64.zip::${_ghurl}/releases/download/${pkgver}/${_appname}_Linux_${pkgver}.zip")
source=(
"LICENSE-${pkgver}::https://raw.githubusercontent.com/MakinoharaShoko/WebGAL_Terre/${pkgver}/LICENSE"
"${pkgname%-bin}.sh"
)
sha256sums=('1f256ecad192880510e84ad60474eab7589218784b9a50bc7ceee34c2b91f1d5'
'655567f68d80966c4d6daf8680f90f23f37eb0c9710e32ddf5620f3be113903f')
sha256sums_aarch64=('e4a6eaa711b341281fff0d7e0fa7b74b86b2d087673feddb7eb50d1fac62de29')
sha256sums_x86_64=('c00476b6a213527b9c17891bd52beb887537770f1293c8834ba37ac438968549')
build() {
sed -e "s|@appname@|${pkgname%-bin}|g" \
-e "s|@runname@|${_appname}|g" \
-i "${srcdir}/${pkgname%-bin}.sh"
gendesk -q -f -n --categories="Game" --name="${_appname//_/ }" --exec="${pkgname%-bin} --no-sandbox %U"
}
package() {
install -Dm755 "${srcdir}/${pkgname%-bin}.sh" "${pkgdir}/usr/bin/${pkgname%-bin}"
install -Dm755 -d "${pkgdir}/opt/${pkgname%-bin}"
cp -r "${srcdir}/release/"* "${pkgdir}/opt/${pkgname%-bin}"
install -Dm644 "${srcdir}/LICENSE-${pkgver}" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 "${pkgdir}/opt/${pkgname%-bin}/assets/templates/WebGAL_Android_Template/app/src/main/ic_launcher-playstore.png" \
"${pkgdir}/usr/share/pixmaps/${pkgname%-bin}.png"
install -Dm644 "${srcdir}/${pkgname%-bin}.desktop" -t "${pkgdir}/usr/share/applications"
}
|