blob: e5e785b3d7c03144178251bb181eaafa2b246019 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: katt <magunasu.b97@gmail.com>
# Contributor: Alfredo Ramos <alfredo dot ramos at yandex dot com>
# Contributor: Christian Rebischke <Chris.Rebischke@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: lucke <lucke at o2 dot pl>
# Contributor: dacoit <dacoit at tuta.io>
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Dmitry Korzhevin <dkorzhevin AT gmail DOT com>
# Contributor: Mark Foxwell <fastfret79@archlinux.org.uk>
# Contributor: tigrmesh <tigrmesh at aol dot com>
# Contributor: Tim Zebulla <amon at faumrahrer dot de>
pkgname=weechat-git
pkgver=4.2.0.r57.g4858d88
pkgrel=1
pkgdesc='Fast, light and extensible IRC client (curses UI). Development version.'
arch=(i686 x86_64 armv7h aarch64)
url=https://weechat.org
license=(GPL-3.0-or-later)
depends=(gnutls curl libgcrypt)
makedepends=(asciidoctor cmake aspell enchant guile lua perl python ruby tcl cjson git)
optdepends=('aspell: spellchecker support'
'enchant: spellchecker support'
'guile: support for guile scripts'
'lua: support for lua scripts'
'perl: support for perl scripts'
'python: support for python scripts'
'ruby: support for ruby scripts'
'tcl: support for tcl scripts'
'cjson: support for relay api')
provides=("${pkgname%-git}=${pkgver}")
conflicts=("${pkgname%-git}")
source=("git+https://github.com/${pkgname%-git}/${pkgname%-git}.git")
sha512sums=('SKIP')
pkgver() {
git -C ${pkgname%-git} describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-rc/rc/g;s/-/./g'
}
# cmake does not correctly handle CPPFLAGS, so kludge it in anyway:
# https://gitlab.kitware.com/cmake/cmake/-/issues/12928
CFLAGS+=" ${CPPFLAGS}"
build() {
cmake -B build -S "${pkgname%-git}" -Wno-dev \
-DCMAKE_INSTALL_PREFIX=/usr \
-DENABLE_MAN=ON \
-DENABLE_DOC=ON \
-DENABLE_DOC_INCOMPLETE=ON \
-DENABLE_ENCHANT=ON \
-DENABLE_JAVASCRIPT=OFF \
-DENABLE_PHP=OFF
make -C build
}
package() {
make -C build DESTDIR="${pkgdir}" install
}
|