blob: a01bcd6491d17849ce832c638e52e273c34eaf43 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
|
# Maintainer: Daniele Basso <d dot bass05 at proton dot me>
## useful links:
# https://www.winehq.org
# https://gitlab.winehq.org/wine/wine
# https://gitlab.winehq.org/wine/wine-staging
# https://github.com/wine-staging/wine-staging
pkgname="wine-staging-wow64"
pkgver=9.8
_pkgver="${pkgver/rc/-rc}"
pkgrel=1
pkgdesc="A compatibility layer for running Windows programs"
url="https://www.winehq.org"
license=(LGPL)
arch=(x86_64)
depends=(
alsa-plugins #lib32-alsa-plugins
fontconfig #lib32-fontconfig
freetype2 #lib32-freetype2
gettext #lib32-gettext
gst-plugins-base-libs #lib32-gst-plugins-base-libs
libpulse #lib32-libpulse
libxcomposite #lib32-libxcomposite
libxcursor #lib32-libxcursor
libxi #lib32-libxi
libxinerama #lib32-libxinerama
libxrandr #lib32-libxrandr
opencl-icd-loader #lib32-opencl-icd-loader
pcsclite #lib32-pcsclite
sdl2 #lib32-sdl2
v4l-utils #lib32-v4l-utils
desktop-file-utils
libgphoto2
# with-wayland
libxkbcommon
wayland
)
_spacehogs=(
samba
sane
)
makedepends=(
# staging
git
libcups #lib32-libcups
libxxf86vm #lib32-libxxf86vm
mesa #lib32-mesa
mesa-libgl #lib32-mesa-libgl
vulkan-icd-loader #lib32-vulkan-icd-loader
autoconf
bison
flex
mingw-w64-gcc
opencl-headers
perl
vulkan-headers
"${_spacehogs[@]}"
)
optdepends=(
alsa-lib #lib32-alsa-lib
cups
dosbox
"${_spacehogs[@]}"
)
provides=(
"wine=$pkgver"
"wine-staging=$pkgver"
"wine-wow64=$pkgver"
)
conflicts=("wine")
install="wine.install"
backup=("usr/lib/binfmt.d/wine.conf")
options=(staticlibs !lto)
source=(
"git+https://gitlab.winehq.org/wine/wine.git#tag=wine-$pkgver"
"30-win32-aliases.conf"
"wine-binfmt.conf"
"git+https://gitlab.winehq.org/wine/wine-staging.git#tag=v$pkgver"
)
b2sums=('10f0afc940897d5f409d7742a0ab3ad21d27a0ae54058ed270cbff84e9396476377fb95f0bd5ad1a02865d7172ea87bb73e085ea1bfb75690d96b07f5c47ce1d'
'45db34fb35a679dc191b4119603eba37b8008326bd4f7d6bd422fbbb2a74b675bdbc9f0cc6995ed0c564cf088b7ecd9fbe2d06d42ff8a4464828f3c4f188075b'
'e9de76a32493c601ab32bde28a2c8f8aded12978057159dd9bf35eefbf82f2389a4d5e30170218956101331cf3e7452ae82ad0db6aad623651b0cc2174a61588'
'ff412adf91a392c0af3e5b5830816616ce4ed4b0826191e8f7b184851aad493c199a2e050fc662f54e67bc0150538a45ec0720362ff90e3526bdf973884cf959')
prepare() {
# apply wine-staging patchset
cd "wine"
"../wine-staging/staging/patchinstall.py" --all
}
build() {
cd "wine"
./configure \
--disable-tests \
--prefix=/usr \
--libdir=/usr/lib \
--with-wayland \
--enable-archs=x86_64,i386
make
}
package() {
cd "wine"
make prefix="$pkgdir"/usr \
libdir="$pkgdir"/usr/lib \
dlldir="$pkgdir"/usr/lib/wine install
ln -sf /usr/bin/wine "$pkgdir"/usr/bin/wine64
# Font aliasing settings for Win32 applications
install -Dm644 "$srcdir"/30-win32-aliases.conf -t "$pkgdir"/usr/share/fontconfig/conf.avail/
install -d "$pkgdir"/usr/share/fontconfig/conf.default
ln -s ../conf.avail/30-win32-aliases.conf "$pkgdir"/usr/share/fontconfig/conf.default/30-win32-aliases.conf
install -Dm644 "$srcdir"/wine-binfmt.conf "$pkgdir"/usr/lib/binfmt.d/wine.conf
}
# vim:set ts=8 sts=2 sw=2 et:
|