PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Torge Matthies <openglfreak@googlemail.com>

_pkgname=winestreamproxy
pkgname=winestreamproxy-git
pkgver=2.0.1.r8.g0482365
pkgrel=1
pkgdesc="Forwards data between a Wine named pipe and a Unix domain socket (Git version)."
arch=('x86_64')
url="https://github.com/openglfreak/winestreamproxy"
license=('MPL2')
depends=('sh' 'wine')
makedepends=('mingw-w64-gcc')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
backup=('etc/xdg/winestreamproxy/settings.conf')
source=("git+https://github.com/openglfreak/winestreamproxy.git#branch=next")
sha256sums=('SKIP')

pkgver() {
    cd "${srcdir}/${_pkgname}"
    git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "${srcdir}/${_pkgname}"
    make out/winestreamproxy_unixlib.dll.so out/winestreamproxy_unixlib.dll.dbg.o
    export CFLAGS="${CFLAGS/-fno-plt/}"
    export LDFLAGS="${LDFLAGS/,-z,relro/}"
    export LDFLAGS="${LDFLAGS/,-z,now/}"
    make release
}

package() {
    cd "${srcdir}/${_pkgname}"
    make DESTDIR="${pkgdir}/usr" PREFIX='/usr' install
    install -dm755 "${pkgdir}/etc/xdg/winestreamproxy"
    mv "${pkgdir}/usr/lib/winestreamproxy/settings.conf" "${pkgdir}/etc/xdg/winestreamproxy/settings.conf"
}