PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer : bug <bug2000 at gmail dot com>
# Contributor: F0ruD <fzerorubigd[at]gmail[dot]com>

pkgname=winswitch
pkgver=0.12.23
pkgrel=3
pkgdesc="Window-Switch is a client server tool to start and control virtual desktops"
arch=('any')
url="https://winswitch.org/"
license=('GPL3')
depends=('pygtk' 'python2-crypto' 'python2-twisted' 'python2-pyasn1' 'hicolor-icon-theme' 'desktop-file-utils')
optdepends=('nautilus: nautilus sendto'
            'thunar: thunar sendto'
            'xpra: xpra support'
            'nss-mdns: mdns support'
            'nxproxy: proxy support'
            'python-netifaces: firewall detection'
            'java-environment: graphical server signatures')
options=('!emptydirs')
install="$pkgname.install"
source=("${url}src/$pkgname-$pkgver.src.tar.bz2")
md5sums=('ef30cc1e9f0f1ecb45f9ae68f7e7ffca')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  # use lib instead of lib64
  sed -i "s|lib64|lib|" setup.py
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  python2 setup.py build
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  python2 setup.py install --root="$pkgdir/"

  # python2 fixes
  sed -i "s/env python/&2/" `grep -rl "env python" "$pkgdir"`
}