blob: 4d2114da5f891967a58f3fca6749b0c956d7d214 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: torculus <20175597+torculus@users.noreply.github.com>
# Contributor: Maxim Baz <archlinux at maximbaz dot com>
pkgname=wluma
pkgver=4.10.0
pkgrel=1
license=('ISC')
pkgdesc='Automatic brightness adjustment based on screen contents and ALS'
url='https://github.com/maximbaz/wluma'
arch=('x86_64' 'aarch64')
depends=('dbus' 'vulkan-icd-loader' 'systemd-libs' 'glibc' 'gcc-libs' 'v4l-utils')
optdepends=('vulkan-driver: for using capturer=wlroots in config.toml'
'wayland: for using capturer=wlroots in config.toml')
makedepends=('cargo' 'clang' 'systemd' 'marked-man')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/maximbaz/${pkgname}/archive/${pkgver}.tar.gz"
"https://github.com/maximbaz/${pkgname}/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz.asc")
b2sums=('bf66622eab4ec630b70dff9c5a3bcc10b371f3b2b3c303446f4c41d28218ccd2c3c7dbb96f24875c792f5825d4b1404d1c054dbac3b7acf62062e51abeb7adff'
'SKIP')
validpgpkeys=('56C3E775E72B0C8B1C0C1BD0B5DB77409B11B601')
prepare() {
cd ${pkgname}-${pkgver}
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd ${pkgname}-${pkgver}
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
marked-man -i README.md -o "${pkgname}.7"
gzip "${pkgname}.7"
}
check() {
cd ${pkgname}-${pkgver}
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features
}
package() {
cd ${pkgname}-${pkgver}
install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 -t "${pkgdir}/usr/lib/udev/rules.d" "90-${pkgname}-backlight.rules"
install -Dm644 -t "${pkgdir}/usr/lib/systemd/user" "${pkgname}.service"
install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}" "README.md"
install -Dm644 -t "${pkgdir}/usr/share/man/man7" "${pkgname}.7.gz"
install -Dm644 -t "${pkgdir}/usr/share/${pkgname}/examples" "config.toml"
}
|