blob: 941ad779c50ba2f707e3f97693e5038773913ba9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>
# Maintainer: Martin Franc <me@martinfranc.eu>
pkgname=wob-git
pkgver=0.13
pkgrel=1
pkgdesc='A lightweight overlay volume/backlight/progress/anything bar for Wayland'
arch=('i686' 'x86_64')
url='https://github.com/francma/wob'
license=('ISC')
source=("git+$url")
sha512sums=('SKIP')
depends=('wayland')
makedepends=('git' 'meson' 'wayland-protocols' 'scdoc' 'libinih')
conflicts=('wob')
provides=("wob=${pkgver%%+*}")
pkgver() {
git -C wob describe --abbrev=10 | sed 's/-/+/; s/-/./'
}
build() {
arch-meson build wob \
-D b_ndebug=true
ninja -C build
}
check() {
ninja -C build test
}
package() {
DESTDIR="$pkgdir" ninja -C build install
install -Dm644 wob/contrib/systemd/wob.service -t "$pkgdir/usr/lib/systemd/user"
install -Dm644 wob/contrib/systemd/wob.socket -t "$pkgdir/usr/lib/systemd/user"
install -Dm644 wob/LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|