PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Maintainer:
# Contributor: Frederic Bezies <fredbezies at gmail dot com>

_pkgname="woof-doom"
pkgname="$_pkgname-git"
pkgver=15.2.0.r444.g3b083e7
pkgrel=2
pkgdesc="Doom port remaining faithful to Lee Killough's MBF on DOS"
arch=("x86_64")
url="https://github.com/fabiangreffrath/woof"
license=('GPL-2.0-or-later')

depends=(
  'hicolor-icon-theme'
  'libebur128'
  'libsndfile'
  'openal'
  'sdl3'
)
makedepends=(
  'cmake'
  'git'
  'ninja'
  'python'
)
optdepends=(
  'fluidsynth'
  'libxmp'
)

provides=("$_pkgname")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 --match='woof_*' \
    | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -Wno-dev
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}