blob: 7f86548be2a3c8fff7e4bd3ce46d3d2d5d11b4aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Firegem <mrfiregem [at] protonmail [dot] ch>
pkgname=wpaperd
pkgver=1.0.0
pkgrel=1
pkgdesc='Wallpaper daemon for Wayland.'
arch=('x86_64')
url='https://github.com/danyspin97/wpaperd'
license=('GPL3')
depends=('libxkbcommon' 'mesa' 'wayland')
makedepends=('cargo' 'scdoc')
provides=("${pkgname}")
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('da072a2c1ace6ef930dce1a3cd8676de492c7277e1c737837a97e8476fdd9cd4')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
cargo fetch --target "${CARCH}-unknown-linux-gnu"
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
scdoc <man/wpaperd-output.5.scd >man/wpaperd-output.5
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
# executable
install -Dm0755 -t "${pkgdir}/usr/bin/" "target/release/${pkgname}"
# man pages
install -Dm0644 -t "${pkgdir}/usr/share/man/man1" man/wpaperd.1
install -Dm0644 -t "${pkgdir}/usr/share/man/man5" man/wpaperd-output.5
# completion
install -Dm0644 completions/${pkgname}.bash "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
install -Dm0644 -t "${pkgdir}/usr/share/fish/vendor_completions.d" completions/${pkgname}.fish
install -Dm0644 -t "${pkgdir}/usr/share/zsh/site-functions" completions/_${pkgname}
install -Dm0644 -t "${pkgdir}/usr/share/elvish/completions" completions/${pkgname}.elv
}
|