summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 8d4f63647d8bee5d91e007835dcabc065d7ff803 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
# Maintainer:

_pkgname="wrapland"
pkgname="$_pkgname"
pkgver=0.600.0
pkgrel=2
pkgdesc='Qt/C++ library wrapping libwayland (kwinft)'
url="https://github.com/winft/wrapland"
license=('LGPL-2.1-only')
arch=('x86_64' 'aarch64')

depends=(
  libglvnd
  qt6-base
  wayland
)
makedepends=(
  clang
  doxygen
  extra-cmake-modules
  git
  lld
  llvm
  microsoft-gsl
  ninja
  wayland-protocols
)

_pkgsrc="$_pkgname-$pkgver"
_pkgext="tar.gz"
source=(
  "$_pkgsrc.$_pkgext"::"$url/archive/refs/tags/v$pkgver.$_pkgext"
)
sha256sums=(
  '2a07b69b6489c2c83f75c346a3aeecf28cc79a7f5040ace467022f554290287e'
)

build() {
  export CC=clang
  export CXX=clang++
  export LDFLAGS+=" -fuse-ld=lld"

  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -DBUILD_TESTING=OFF
    -Wno-dev
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}