blob: 5ea149d610e216b9377f152c02f6c117c68aa3eb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
|
# Maintainer: Jingbei Li <i@jingbei.li>
# Contributor: codestation <codestation404 at gmail dot com>
pkgname=wxmedit
pkgver=3.2
pkgrel=1
pkgdesc="Cross-platform Text/Hex Editor, a fork of MadEdit with bug fixes and improvements"
arch=("i686" "x86_64")
url="https://wxmedit.github.io/"
license=('GPL-3.0-or-later')
depends=('curl' 'gcc-libs' 'glib2' 'glibc' 'gtk3' 'hicolor-icon-theme' 'icu' 'wxwidgets-common' 'wxwidgets-gtk3')
makedepends=('boost')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/hltj/wxMEdit/archive/$pkgver.tar.gz")
sha256sums=('d2bdf266125c6df724ec78cb99ef5f043fca28e8e873eac4b49db7b5986c7579')
build() {
cd "$srcdir/wxMEdit-$pkgver"
# ICU >= 77 requires C++17; configure hardcodes -std=c++11, patch it
sed -i 's/-std=c++11/-std=c++17/g; s/-std=c++0x/-std=c++17/g' configure
./configure --prefix=/usr --with-wx-config=/usr/bin/wx-config icu_LIBS="-licui18n -licuuc"
make
}
package() {
cd "$srcdir/wxMEdit-$pkgver"
make DESTDIR="${pkgdir}" install
}
|