blob: 9c8c8eefd236b356652a69e53a93f1cd7b78444c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor: Eric Bélanger <eric@archlinux.org>
pkgname=wxpython-light
pkgver=3.0.2.0
pkgrel=2
pkgdesc="A wxWidgets GUI toolkit for Python (GNOME/GStreamer free!)"
arch=('i686' 'x86_64')
license=('custom:wxWindows')
url='http://www.wxpython.org'
depends=('wxgtk-light'
'python2-opengl'
'python2-cairo'
)
makedepends=('git'
'svn'
'mesa'
)
provides=('wxpython')
conflicts=('wxpython')
source=("git+https://github.com/wxWidgets/wxPython.git#tag=wxPy-${pkgver}"
'svn+http://svn.wxwidgets.org/svn/wx/wxPython/3rdParty/AGW/agw'
'svn+http://svn.wxwidgets.org/svn/wx/wxPython/3rdParty/FloatCanvas/floatcanvas'
'svn+http://svn.wxwidgets.org/svn/wx/wxPython/3rdParty/PDFViewer/pdfviewer'
'svn+http://svn.wxwidgets.org/svn/wx/wxPython/3rdParty/PubSub/pubsub'
'svn+http://svn.wxwidgets.org/svn/wx/wxPython/3rdParty/XRCed'
'svn+http://svn.wxwidgets.org/svn/wx/wxPython/3rdParty/Editra')
sha1sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP')
prepare() {
cd wxPython/wxPython/wx/lib
cp -R ${srcdir}/agw .
cp -R ${srcdir}/floatcanvas .
cp -R ${srcdir}/pdfviewer .
cp -R ${srcdir}/pubsub .
cd ../tools
cp -R ${srcdir}/XRCed .
cp -R ${srcdir}/Editra .
sed 's|sys.exit(1)||' -i "Editra/setup.py"
cd "${srcdir}"
# Make sure really use python2
find . -type f -exec sed -i 's/env python/env python2/' {} \;
}
build() {
cd wxPython
./configure --prefix=/usr --libdir=/usr/lib \
--with-{gtk=2,libjpeg=sys,libpng=sys,libtiff=sys,libxpm=sys,regex=builtin,opengl,sdl} \
--without-{libnotify,gnomevfs,gnomeprint} \
--enable-{graphics_ctx,unicode} \
--disable-{mediactrl,precomp-headers,webview}
cd wxPython
python2 setup.py WXPORT=gtk2 UNICODE=1 BUILD_GLCANVAS=1 build
}
package() {
cd wxPython/wxPython
python2 setup.py WXPORT=gtk2 UNICODE=1 BUILD_GLCANVAS=1 install --root="${pkgdir}"
install -D -m644 ../docs/licence.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd wx/tools/Editra
python2 setup.py install --root="${pkgdir}"
rm -r "${pkgdir}/usr/lib/python2.7/site-packages/wx-3.0-gtk2/wx/tools/Editra"
}
|