summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c549ceece2509f803195ead8c53912f3859218f2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Maintainer: Christian Hesse <mail@eworm.de>
# Contributor: Jakub Luzny <limoto94@gmail.com>

pkgname=x86info
_commit='9501749231164135db25c72cbeb42bf32af1519b'
pkgver=1.30.158
pkgrel=1
pkgdesc='A CPU identification utility. Provides more info than /proc/cpuinfo'
arch=('i686' 'x86_64')
depends=('pciutils')
url='https://github.com/kernelslacker/x86info'
license=('GPL')
install=x86info.install
makedepends=('git')
source=("git://github.com/kernelslacker/x86info.git#commit=${_commit}")
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/${pkgname}/"

	# Version 1.30 is latest release, but it does not have a tag.
	# So count from commit...
	echo "1.30.$(git rev-list --count b69b850c50..)"
}

build() {
	cd "${srcdir}/${pkgname}/"

	make

	cd lsmsr/

	make
}

package() {
	cd "${srcdir}/${pkgname}/"

	install -D -m0775 x86info "${pkgdir}/usr/bin/x86info"
	install -D -m0775 lsmsr/lsmsr "${pkgdir}/usr/bin/lsmsr"
	install -D -m0644 x86info.1 "${pkgdir}/usr/share/man/man1/x86info.1"
	install -D -m0644 lsmsr/lsmsr.8 "${pkgdir}/usr/share/man/man8/lsmsr.8"
}