summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b92f85e6c6061a6918a41c2174574e640320aa22 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Brian Bidulock <bidulock@openss7.org>

pkgname=xde-menu-git
_pkgname=xde-menu
pkgver=0.11.r0.g7fce7e4
pkgrel=2
pkgdesc="XDG compliant menu generator"
arch=('i686' 'x86_64')
url="https://github.com/bbidulock/xde-menu"
groups=('xde-git')
license=('GPL')
provides=($_pkgname=$pkgver)
conflicts=($_pkgname)
depends=('libwnck+-git' 'libsm' 'gnome-menus')
makedepends=('git')
optdepends=('xdg-launch-git: for LW WM launch notification'
	    'xde-theme: for LW WM style and theme change support')
source=("$pkgname::git+https://github.com/bbidulock/$_pkgname.git")
md5sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --long --tags | sed -E 's/([^-]*-g)/r\1/;s/-/./g'
}

prepare() {
  cd $pkgname
  ./autogen.sh
}

build() {
  cd $pkgname
  ./configure
  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}

# vim: et sw=2: