blob: 8d377f7f8859e75c4579e7fe9d4d253a8f50b6d2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=xdg-desktop-portal-cosmic-git
pkgver=r124.db02412
pkgrel=1
pkgdesc="A backend implementation for xdg-desktop-portal for the COSMIC desktop environment"
arch=('x86_64' 'aarch64')
url="https://github.com/pop-os/xdg-desktop-portal-cosmic"
license=('GPL-3.0-or-later')
groups=('cosmic')
depends=(
'hicolor-icon-theme'
'libpipewire'
'libxkbcommon'
'mesa'
'wayland'
'xdg-desktop-portal'
)
makedepends=(
'cargo'
'clang'
'git'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/pop-os/xdg-desktop-portal-cosmic.git')
sha256sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${pkgname%-git}"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
make vendor
# libexec > lib
sed -i 's|libexecdir = $(prefix)/libexec|libexecdir = $(libdir)|g' Makefile
}
build() {
cd "${pkgname%-git}"
make prefix='/usr' VENDOR='1' all
}
package() {
cd "${pkgname%-git}"
make prefix='/usr' DESTDIR="$pkgdir" install
}
|