blob: a97529339591c18a16d5e9e719c1a3be45b4117b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
pkgbase=xet
pkgname=(git-xet xetcmd xetmnt)
pkgver=0.13.2
pkgrel=1
pkgdesc='CLI tools for working with XetHub'
arch=(x86_64)
url=https://xethub.com
_url='https://github.com/xetdata/xet-core'
license=(BSD)
depends=(gcc-libs
glibc
openssl
zlib libz.so)
makedepends=(cargo
protobuf
openssl)
_archive="xet-core-$pkgver"
options=(!lto)
source=("$_url/archive/v$pkgver/$_archive.tar.gz")
sha256sums=('bfabea8751dd9f11c7d9d9e70b2d8c26915dd34c01e66891710c037e7625f713')
prepare() {
cd "$_archive/rust"
cargo update
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$_archive/rust"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
CFLAGS+=' -ffat-lto-objects'
cargo build --frozen --release --all-features
}
_package() {
cd "$_archive/rust"
install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" ../LICENSE
}
package_git-xet() {
_package
}
package_xetcmd() {
_package
}
package_xetmnt() {
depends+=(git-xet)
_package
}
|