blob: 64cd42e9890d9b480781a8f8350253fe5cb5c939 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: AndyRTR <andyrtr@archlinux.org>
# Contributor: Paul Mattal <paul@mattal.com>
# Contributor: Juergen Hoetzel <juergen@hoetzel.info>
pkgname=xf86-video-openchrome
_commit=0c752742e54fa34140386547947c81a832c9cad1 # master 2022-09-21 // v0.6.602
pkgver=0.6.0.r798.g0c75274
#pkgver=0.6.0
pkgrel=2
pkgdesc="X.Org Openchrome drivers"
arch=(x86_64)
license=('custom')
url="https://www.freedesktop.org/wiki/Openchrome/"
depends=('libdrm' 'libxvmc' 'systemd-libs')
makedepends=('xorg-server-devel' 'X-ABI-VIDEODRV_VERSION=25.2' 'systemd' 'libxv'
'git')
conflicts=('xorg-server<21.1.1' 'X-ABI-VIDEODRV_VERSION<25' 'X-ABI-VIDEODRV_VERSION>=26'
'xf86-video-via' 'xf86-video-unichrome' 'openchrome')
replaces=('openchrome' 'xf86-video-via')
groups=('xorg-drivers')
options=('!emptydirs')
#source=(https://xorg.freedesktop.org/archive/individual/driver/${pkgname}-${pkgver}.tar.bz2{,.sig})
#sha256sums=('da2975c6379358de52c1257710c67eb59139a7f0a1cd28d00cc64cc3e1c02f75'
# 'SKIP')
source=("git+https://anongit.freedesktop.org/git/openchrome/xf86-video-openchrome#commit=${_commit}")
sha256sums=('SKIP')
validpgpkeys=('CDA92E38A7A7A82237E9AB61C922784178BFFDB0') # "Kevin Brace <kevinbrace@gmx.com>"
pkgver() {
cd $pkgname
#git describe --long | sed 's/-/+/g'
# git describe --long | sed "s/openchrome-//;s/-/./g"
git describe --long | sed 's/^xf86-video-openchrome-//;s/\([^-]*-g\)/r\1/;s/-/./g'
# git describe --long | sed "s/openchrome-//;s/0.5/0.5.200/;s/-/+/g"
# git describe --long | sed "s/openchrome-//;s/0.5/0.5.0/;s/-/+/g"
}
prepare() {
cd $pkgname
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd ${pkgname} #-${pkgver}
# Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
# With them, module fail to load with undefined symbol.
# See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
export CFLAGS=${CFLAGS/-fno-plt}
export CXXFLAGS=${CXXFLAGS/-fno-plt}
export LDFLAGS=${LDFLAGS/,-z,now}
./configure --prefix=/usr
make
}
check() {
cd ${pkgname} #-${pkgver}
make check
}
package() {
cd ${pkgname} #-${pkgver}
make DESTDIR="${pkgdir}" install
install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}
|